Découvrez comment vous pouvez ajouter des rappels d'anniversaire à votre base de données Access. Soyez informé si l'anniversaire de votre client ou de votre employé approche afin de pouvoir lui envoyer vos salutations chaleureuses.
L'envoi de vœux d'anniversaire peut être un excellent moyen de se connecter et de renforcer la relation avec un client ou un employé. Si vous gérez une base de données Access contenant des enregistrements de clients/employés, il peut être intéressant d'être averti de temps à autre si l'anniversaire d'un client ou d'un employé approche. Dans ce didacticiel, vous apprendrez comment créer une fonction qui vous avertira du jour spécial de quelqu'un au moment où vous ouvrirez la base de données.
Téléchargez
Si vous souhaitez commencer à utiliser cette fonctionnalité dès que possible, vous pouvez :
Téléchargez l'exemple de base de données avec les codes VBA maintenant
Sinon, si vous voulez bricoler, vous pouvez lire le contenu ci-dessous.
Prérequis
Ce tutoriel suppose que vous avez une table dans votre base de données qui contient ces 3 champs : prénom, nom et anniversaire.
Étapes pour ajouter des rappels d'anniversaire dans la base de données Access
- Créez une nouvelle table et nommez-la AnniversaireCélébrants. Cela servira de référentiel pour la liste des célébrants d'anniversaire. Ajoutez 3 champs comme indiqué ci-dessous. Pas besoin de clé primaire.
- Créez un formulaire pour BirthdayCelebrants. Ce formulaire apparaîtra à l'ouverture de la base de données s'il y a des anniversaires à venir.
- Dans le volet de navigation, sélectionnez la table BirthdayCelebrants.
- Allez dans Créer > Formulaire.
- Un formulaire unique sera automatiquement créé pour vous.
Étant donné que nous allons afficher une liste des célébrants d'anniversaire, je vous suggère de modifier la vue par défaut du formulaire en feuille de données ou en formulaires continus. De cette façon, vous pouvez avoir un aperçu rapide de la liste.
- En mode création, sélectionnez le formulaire.
- Ouvrez la feuille de propriétés (ALT + F11)
- Allez dans Format > Affichage par défaut.
- Sélectionnez la vue souhaitée – Feuille de données ou Formulaires continus.
Si vous avez sélectionné des formulaires continus, modifiez le design en fonction de vos préférences. Voici à quoi ressemble le mien :
J'ai modifié le format de la zone de texte Anniversaire afin que les valeurs soient affichées au format Date longue. De plus, j'ai fait les mises à jour suivantes sur les propriétés du formulaire :
- Autoriser les ajouts : non
- Autoriser les suppressions : non
- Autoriser les modifications : non
Une fois terminé, fermez le formulaire et enregistrez-le sous frm_BirthdayCelebrants.
- Ajoutez le code pour le rappel d'anniversaire.
- Ajouter un nouveau module.
- Cela ouvrira l'éditeur VBA.
- Ajoutez le code suivant et modifiez-le selon vos besoins.
- Ajouter un nouveau module.
Public Function RunBirthdayReminders()
Dim qry As String, fld_fName As String, fld_lName As String, fld_birthday As String, tbl As String
Dim db As DAO.Database, rst As DAO.Recordset
'TO DO: Update the ff. variables with the actual name of your table and fields
tbl = "Members" 'table containing your client/employee reocrds
fld_fName = "FirstName" 'first name field
fld_lName = "LastName" 'last name field
fld_birthday = "Birthday" 'birthday field
Set db = CurrentDb
'delete current record(s) from BirthdayCelebrants table
DoCmd.SetWarnings False
DoCmd.RunSQL ("DELETE FROM BirthdayCelebrants")
DoCmd.SetWarnings True
'insert new record(s) in BirthdayCelebrants table using a query that gets list of people celebrating their birthday today.
qry = "INSERT INTO BirthdayCelebrants " & _
"SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
"Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")=Day(Date())"
DoCmd.SetWarnings False
DoCmd.RunSQL (qry)
DoCmd.SetWarnings True
Set rst = db.OpenRecordset("SELECT * FROM BirthdayCelebrants")
If Not rst.EOF Then
DoCmd.OpenForm ("frm_BirthdayCelebrants")
End If
Set db = Nothing
Set rst = Nothing
End Function
Veuillez noter que le code ci-dessus utilise une requête qui obtient une liste des célébrants d'anniversaire pour la journée en cours. Si vous souhaitez obtenir une liste des personnes dont l'anniversaire approche pour le mois en cours, utilisez plutôt la requête suivante.
'insert new record(s) in BirthdayCelebrants table using a query that gets list of people whose birthday is coming up for this month.
qry = "INSERT INTO BirthdayCelebrants " & _
"SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
"Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")>=Day(Date())" & _
" ORDER BY Day(" & fld_birthday & ") ASC"
- Enfin, nous allons créer une macro AutoExec. Cela exécutera le code lors de l'ouverture de la base de données.
- Allez dans Créer > Macro.
- Sélectionner Code d'exécution dans la liste déroulante.
- Pour le nom de la fonction, écrivez Exécuter des rappels d'anniversaire ().
- Enregistrez la macro sous Exécution automatique et cliquez sur OK.
- Maintenant, testez votre rappel d'anniversaire.
Fermez la base de données et rouvrez-la. S'il y a des anniversaires à venir, le formulaire de rappel d'anniversaire devrait apparaître. S'il n'y en a pas, la base de données fonctionnera comme d'habitude.
Rappel rapide
Maintenant, pour un rappel rapide. Si un jour, vous ne parvenez pas à ouvrir votre base de données, pas de panique. Effectuez les démarches nécessaires pour le récupérer. Si vous ne pouvez toujours pas, essayez un logiciel tiers qui réparer l'accès. Il y a encore de l'espoir.
Introduction de l'auteur:
Jayme Stack est un expert en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération SQL et des produits logiciels de récupération Excel. Pour plus d'informations, visitez www.datanumen.com




