4 méthodes pour extraire des tableaux d'un document Word à un autre

Dans cet article, nous sommes heureux de vous montrer 4 méthodes pour extraire plusieurs tableaux d'un document Word à un autre.

Le tableau est le most utilisé signifie que nous utilisons pour conserver des informations tabulaires. Il organise les données en lignes et en colonnes, offrant aux lecteurs une vue claire de toutes les informations. Un long document peut contenir de nombreux tableaux, il est donc nécessaire de les exporter vers un nouveau document à des fins diverses.

Voici nos 4 approches.

Méthode 1 : Exporter par lots tous les tableaux d'un document à un autre

1. Premier et premierost, appuyez sur "Alt + F11" pour déclencher l'éditeur VBA dans Word.
2. Cliquez ensuite sur le projet "Normal" et l'onglet "Insérer" ensuite.
3. Choisissez "Module" dans le menu déroulant.
4. Et double-cliquez pour ouvrir le module et faire apparaître l'espace d'édition sur le côté droit.
5. Copiez et collez maintenant la macro suivante ici :

Sub ExtractTablesFromOneDoc()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
 
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  For Each objTable In objDoc.Tables
    objTable.Range.Select
    Selection.Copy
 
    '  Paste tables to new document in rich text format.
    Set objRange = objNewDoc.Range
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.PasteSpecial DataType:=wdPasteRTF
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.Text = vbCr
  Next objTable
 
End Sub

6. Enfin, cliquez sur «Exécuter».

Cette macro extraira également les tableaux et leurs légendes.

Méthode 2 : Extraire un tableau spécifique d'un document

Maintenant, au cas où il y aurait beaucoup de tables dans votre document, mais vous devez envoyer une table particulière à quelqu'un. Ensuite, la macro suivante vous aidera beaucoup.

1. Tout d'abord, installez et exécutez la macro en suivant les étapes de la méthode 1.
2. Deuxièmement, remplacez cette macro par celle-ci :

Sub ExtractSpecificTables()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
  Dim strTable As String
 
  strTable = InputBox("Enter the table number: ")
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  objDoc.Tables(strTable).Range.Select
  Selection.Copy
 
  Set objRange = objNewDoc.Range
  objRange.Collapse Direction:=wdCollapseEnd
  objRange.PasteSpecial DataType:=wdPasteRTF
 
End Sub

3. Maintenant, une boîte de saisie apparaîtra.
4. Entrez un numéro de table et cliquez sur "OK".

Méthode 3 : Extrayez par lots toutes les tables de plusieurs documents

1. À start avec, organisez tous les fichiers dans un dossier.
2. Ensuite, installez et exécutez une macro avec les instructions exactes ci-dessus.
3. Remplacez la macro par celle-ci :

Sub ExtractTablesFromMultiDocs()
  Dim objTable As Table
  Dim objDoc As Document, objNewDoc As Document
  Dim objRange As Range
  Dim strFile As String, strFolder As String
 
  '  Initialization
  strFolder = InputBox("Enter folder address here: ")
  strFile = Dir(strFolder & "\" & "*.docx", vbNormal)
 
  Set objNewDoc = Documents.Add
 
  '  Process each file in the folder.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & "\" & strFile)
    Set objDoc = ActiveDocument
 
    For Each objTable In objDoc.Tables
      objTable.Range.Select
      Selection.Copy
 
      Set objRange = objNewDoc.Range
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.PasteSpecial DataType:=wdPasteRTF
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.Text = vbCr
    Next objTable
 
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
 
End Sub

4. Maintenant, dans la boîte de dialogue, entrez l'adresse du dossier où vous stockez vos documents et cliquez sur "OK".

Méthode 4 : Copier les tables manuellement

Cependant, si vous ne vous sentez pas à l'aise avec VBA, vous pouvez faire le travail manuellement tant qu'il y a un nombre limité de tables.

1. Tout d'abord, cliquez sur le signe plus dans le coin supérieur gauche pour sélectionner tarobtenir un tableau.
2. Appuyez ensuite sur "Ctrl + C" pour le copier.
3. Ouvrez ensuite un nouveau document.
4. Et appuyez sur "Ctrl + V" pour coller le tableau dans un nouveau document.
5. N'oubliez pas d'enregistrer le nouveau document.

Gérer les problèmes de documents

Tant que nous continuerons à utiliser Word, il y aura toujours Dégâts de mots. Cependant, n'ayez plus peur. Ce n'est plus un problème insoluble. Avec un outil de récupération qualifié, vous avez de grandes chances de récupérer toutes vos précieuses données.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris xlsx corrompu et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com