3 façons d'insérer rapidement des sauts de section dans votre document Word

Dans cet article, nous allons nous concentrer sur vous montrer 3 façons d'insérer rapidement des sauts de section dans votre document Word.

Les sauts de section sont utiles pour diviser un document en sections, chapitres, etc. De plus, insérer des sauts de section est un élément indispensable pour définir différents en-têtes ou pieds de page sur différentes pages.

Normalement, nous devrons naviguer vers la page et placer le curseur à la bonne position. Cliquez ensuite sur "Mise en page" et "Sauts". Et puis choisissez un type de saut de section dans le menu déroulant. Une telle démarche peut parfois être fastidieuse. Par conséquent, nous voulons vous épargner de la routine habituelle et adopter une solution rapide et sale.

Méthode 1 : Insérer un saut de section sur une page spécifique

1. Tout d'abord, appuyez sur "Alt + F11" dans Word pour appeler l'éditeur VBA.
2. Créez ensuite un nouveau module en cliquant sur "Normal" dans la colonne de gauche.
3. Cliquez ensuite sur l'onglet "Insérer" dans la barre de menu.
4. Et choisissez "Module" dans le menu déroulant de "Insérer".
5. Double-cliquez sur le nouveau module pour l'ouvrir.
6. Collez la macro suivante sur la zone de codage :

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Maintenant, cliquez sur "Exécuter" ou appuyez sur "F5" pour exécuter les codes.
8. Saisissez ensuite le numéro de la page cible dans la zone de texte prévue à cet effet. Cliquez ensuite sur « OK » pour continuer.

Jusqu'à présent, vous avez inséré un saut de section à la fin de la page 2.

Note:

Si vous souhaitez séparer plusieurs pages consécutives en une section à l'aide de sauts de section, vous devez insérer deux sauts de section, un à la fin de la dernière page de la section précédente et un à la fin de la dernière page de cette nouvelle section .

Dans un tel cas, lors de l'insertion de la première rupture, vous devez vous rappeler d'entrer le numéro correct qui est le numéro de page de la dernière page de la section précédente.

Méthode 2 : Insérer un saut de section sur chaque page d'un document

1. Tout d'abord, installez et exécutez une macro en suivant exactement les étapes ci-dessus.
2. Remplacez ensuite la macro par celle-ci :

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Cette macro insère un saut de section à la fin de chaque page du document en cours.

Méthode 3 : Insérer un saut de section sur chaque page de plusieurs documents

1. Pour commencer, placez tous les documents cibles dans le même dossier.
2. Ensuite, de la même manière, installez et exécutez la macro avec les instructions appropriées.
3. Cette fois, utilisez ces codes :

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. La macro doit déclencher la fenêtre "Parcourir". Choisissez le dossier dans lequel vous conservez les documents et cliquez sur "OK".

Le processus ne prendra pas plus de quelques secondes.

Outil pratique pour la corruption de documents

C'est une expérience frustrante de rencontrer des documents endommagés. Dans un tel scénario, un bon outil fiable qui peut aider mot de réparation documents doivent pouvoir soulager beaucoup son anxiété. Par conséquent, vous devez être extrêmement prudent lors du choix d'un outil de réparation. Une utilité insuffisante peut causer des dommages supplémentaires.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris Récupération Excel et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com