3 méthodes utiles pour effacer par lots tous les styles de tableau dans votre document Word

Dans cet article, nous nous concentrerons sur la démonstration de 3 méthodes utiles pour effacer par lots tous les styles de tableau de votre document Word.

De temps en temps, si un tableau Word est appliqué avec un style indésirable ou s'il réduit l'effet visuel de l'ensemble du document, vous devez effacer son style. Voyons maintenant comment accomplir une telle tâche.

Méthode 1 : effacer le style d'un tableau de mots

1. Avant toute chose, déplacez le curseur sur le tableau cible jusqu'à ce que vous voyiez le signe en forme de croix dans le coin supérieur gauche du tableau.
2. Cliquez ensuite sur la croix pour sélectionner l'ensemble du tableau.
3. Vous avez maintenant déclenché les "Outils de table". Cliquez sur l'onglet "Conception".
4. Cliquez ensuite sur le bouton "Plus" dans le groupe "Styles de tableau" pour afficher le menu déroulant.
5. Choisissez l'option "Effacer".
6. Maintenant, le style de tableau est supprimé. Il en va de même pour toutes les bordures de table. Pour ajouter des bordures au tableau, assurez-vous que le tableau est sélectionné. Et cliquez sur le bouton déroulant à côté de la commande "Bordures".
7. Et choisissez "Toutes les bordures".

Voici le résultat:

Méthode 2 : Effacer par lots tous les styles de tableau dans un seul document

Une fois que nous avons fait la table unique, le sujet du traitement par lots ne peut pas être manqué. Voyons d'abord comment effacer tous les styles de tableau dans un document via VBA.

1. Pour commencer, appuyez sur « Alt+F11 » pour afficher l'éditeur VBA dans Word.
2. Cliquez ensuite sur le projet "Normal" dans la colonne de gauche.
3. Cliquez ensuite sur "Insérer" dans la barre de menu.
4. Et choisissez "Module" dans le menu déroulant.
5. Ouvrez l'espace de codage du module en double-cliquant dessus.
6. Collez-y maintenant la macro suivante :

Sub ClearTableStylesInADoc()
  Dim objTable As Table
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
  Set objDoc = ActiveDocument
 
  For Each objTable In objDoc.Tables
    objTable.Style = "Table Normal"
    objTable.Borders.Enable = True
  Next objTable
 
  Application.ScreenUpdating = True
 
  Set objDoc = Nothing
End Sub

7. Cliquez enfin sur « Exécuter ».

Cette macro efface tous les styles de tableau d'un document, leur applique le style "Tableau normal" et ajoute également des bordures de tableau.

Méthode 3 : Effacer par lots tous les styles de tableau dans plusieurs documents

Maintenant, au cas où vous auriez quelques documents à traiter, voici la macro pour effacer tous les styles de tableau dans plusieurs documents.

1. Tout d'abord, organisez tous les documents dans un dossier.
2. Les étapes répétées de la méthode 2 pour installer et exécuter une macro.
3. Seulement cette fois, pensez à remplacer par cette macro :

Sub ClearTableStylesInMultiDoc()
  Dim objTable As Table
  Dim objDoc As Document
  Dim StrFolder As String
  Dim strFile As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
 
    For Each objTable In objDoc.Tables
      objTable.Style = "Table Normal"
      objTable.Borders.Enable = True
    Next objTable
 
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. En exécutant la macro, il y aura la fenêtre "Parcourir". Sélectionnez le dossier dans lequel vous stockez le document à l'étape 1 et cliquez sur "OK".

Laissez ensuite le reste du travail à la macro.

Moyens de récupérer des documents perdus

Par documents perdus, nous entendons les documents compromis en raison de Corruption de mots ou des erreurs humaines. Lorsque vous traitez de tels documents, vous devez toujours garder à l'esprit qu'ils peuvent être récupérés à l'aide d'un outil de réparation avancé.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation xls et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com