2 façons de fusionner rapidement plusieurs documents Word en un seul via VBA

Dans cet article, nous sommes heureux de partager avec vous 2 façons de fusionner rapidement plusieurs documents Word en un seul via VBA.

Dans Word, il existe une fonctionnalité intégrée par défaut pour aider l'utilisateur à combiner ou à fusionner plusieurs documents en un seul. Les détails sont expliqués dans cet article : Comment combiner et fusionner plusieurs documents Word en un seul

Avec cette méthode, vous devez faire quelques clics et le contenu du document suivant vient toujours juste après celui du précédent. Par conséquent, nous souhaitons vous proposer des moyens plus rapides de le faire.

Méthode 1 : fusionner les documents sélectionnés en un seul

1. Avant toute chose, créez un nouveau document vierge.
2. Déclenchez l'éditeur VBA dans Word en appuyant sur "Alt + F11".
3. Cliquez ensuite sur "Normal".
4. Cliquez ensuite sur "Insérer".
5. Et choisissez "Module".
6. Double-cliquez sur nouveau module pour ouvrir l'espace d'édition.
7. Collez-y la macro suivante :

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Cliquez ensuite sur "Exécuter" ou appuyez sur "F5".
9. Maintenant, dans la fenêtre "Parcourir", sélectionnez plusieurs fichiers en appuyant sur "Ctrl" et cliquez sur "OK".
10. Ensuite, tout le contenu des fichiers sélectionnés sera assemblé dans le nouveau document, le texte de chaque document commençant sur une nouvelle page.

Remarque:

Comme nous l'avons mentionné, cette macro place les textes de chaque document sur une nouvelle page. Mais si vous avez besoin qu'ils soient l'un après l'autre, vous pouvez modifier certaines lignes de code dans la macro. Trouvez simplement la ligne "If nEachSelectedFile <nTotalFiles Then", puis supprimez-la ainsi que les six lignes suivantes.

Méthode 2 : fusionner tous les documents d'un dossier en un seul

Si vous avez un dossier de fichiers à combiner, cette macro fonctionnera à merveille.

1. Pour commencer, installez et exécutez la macro comme décrit dans la méthode 1.
2. Remplacez ensuite macro par celle-ci :

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Exécutez la macro en cliquant sur "Exécuter".
4. Ensuite, vous voyez la fenêtre "Parcourir" ouverte. Sélectionnez le dossier dans lequel vous stockez tous les documents. Et cliquez sur "OK".

De même, le texte de chaque document commence sur une nouvelle page. Pour qu'ils se suivent, recherchez et supprimez la ligne de code «.InsertBreak Type:=wdPageBreak».

Protégez correctement votre document Word

L'un des meilleurs moyens de protéger vos documents Word consiste à les sauvegarder régulièrement. Avec les sauvegardes en main, vous n'aurez jamais à craindre la perte de données. En outre, il est également conseillé de se procurer un outil pour réparation docx si l'un d'eux est endommagé.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris Excel endommagé et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com