2 façons d'imprimer les listes de tâches Outlook avec différentes catégories dans différentes pages

Si vous avez attribué différentes catégories de couleurs à vos tâches Outlook et que vous souhaitez maintenant imprimer les listes de tâches avec différentes catégories dans différentes pages, vous pouvez vous référer à cet article. Ici, nous allons vous partager 2 méthodes pour l'obtenir.

Afin de classer et bien gérer vos tâches, vous avez peut-être appliqué des catégories de couleurs à vos tâches. Maintenant, si vous souhaitez imprimer les listes de vos tâches avec différentes catégories sur différentes pages, lisez la suite. Dans ce qui suit, nous allons vous présenter 2 moyens pour l'obtenir.

Méthode 1 : Imprimer manuellement les listes de tâches une par une

1. Tout d'abord, dans Outlook, accédez au volet "Tâches".
2. Ensuite, ouvrez un dossier de tâches.
3. Ensuite, appuyez sur "Ctrl + E" pour activer le ruban "Rechercher".
4. Après cela, dans l'onglet "Rechercher", cliquez sur le bouton "Catégoriser".
5. Dans la liste déroulante, choisissez une catégorie de couleur.
6. Ensuite, seules les tâches avec la catégorie sélectionnée seront laissées dans la liste.
7. Maintenant, allez dans "Fichier"> "Imprimer" pour imprimer cette liste de tâches.
8. Ensuite, de la même manière, imprimez les listes de tâches avec les autres catégories de couleurs une par une manuellement.

Méthode 2 : impression par lots des listes de tâches par VBA

1. Au tout début, lancez l'éditeur VBA conformément à "Comment exécuter le code VBA dans votre Outlook" .
2. Ensuite, ajoutez la référence à « MS Excel Object Library » comme indiqué dans «Comment ajouter une référence à une bibliothèque d'objets en VBA" .
3. Ensuite, copiez le code VBA suivant dans un module.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Ensuite, appuyez sur la touche "F5" pour exécuter cette macro immédiatement.
5. Lorsque la macro se termine, les listes de tâches avec différentes catégories seront imprimées sur différentes pages, comme indiqué dans la capture d'écran suivante.

Récupérer des données précieuses à partir d'un fichier PST compromis

Si vous êtes sujet à un fichier PST inaccessible, votre prochaine étape est sans aucun doute Réparation PST. Dans ce cas, vous pouvez d'abord essayer l'outil de réparation de la boîte de réception. En cas d'échec, vous pouvez continuer à essayer un autre outil externe, tel que DataNumen Outlook Repair. Il est capable de récupérer des données PST en un temps record.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com