2 méthodes pour compter rapidement les e-mails par expéditeur dans votre Outlook

Si vous souhaitez compter les emails par expéditeur, vous pouvez vous référer à cet article. Ici, nous allons vous exposer 2 approches rapides.

Pour identifier l'expéditeur le plus actif, vous pouvez compter les e-mails par expéditeur. Bien qu'Outlook ne propose pas de fonctionnalité dédiée, il existe des solutions alternatives, comme la méthode 1. Si vous la trouvez trop fastidieuse, vous pouvez opter pour la méthode 2. Bien plus efficace, elle utilise VBA pour compter rapidement les e-mails par expéditeur et exporter les résultats vers Excel. Poursuivez votre lecture pour découvrir ces deux méthodes en détail. Prenons l'exemple des e-mails de la boîte de réception.

Méthode 1 : Obtenir les décomptes après avoir regroupé les éléments par champ "De"

1. Pour commencer, lancez l'application Outlook.
2. Ensuite, ouvrez le dossier de la boîte de réception.
3. Ensuite, passez à l'onglet "Affichage".
4. Ensuite, choisissez "De" dans le groupe "Arrangement".
5. À la fois, tous les éléments de la boîte de réception ont été séparés en différents groupes selon les différents expéditeurs.
6. Maintenant, pour compter les éléments d'un expéditeur spécifique, vous pouvez sélectionner tous les éléments du groupe associé et appuyer sur la touche "Entrée". Dans l'avertissement contextuel, vous pouvez voir le nombre.

Cela signifie que c'est assez simple, mais le nombre d'éléments inclut en fait les autres types d'éléments, tels que les invitations à des réunions, les demandes de tâches et les reçus, et pas seulement le nombre d'e-mails. Ainsi, si vous ne souhaitez compter que les e-mails, vous pouvez utiliser la méthode suivante à la place.

Méthode 2 : compter les e-mails par expéditeur avec Outlook VBA

1. Pour commencer, appuyez sur les touches « Alt + F11 » dans Outlook.
2. Ensuite, activez « Bibliothèque d’objets MS Excel » conformément à « Comment ajouter une référence à une bibliothèque d'objets en VBA" .
3. Ensuite, copiez le code ci-dessous dans un module inutilisé.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Après cela, appuyez sur la touche "F5".
4. Lorsque la macro se termine, un nouveau fichier Excel s'affiche.
5. Comme vous pouvez le voir, il contient le nombre d'e-mails de boîte de réception provenant de différents expéditeurs.

Débarrassez-vous des problèmes frustrants d'Outlook

Peut-être avez-vous déjà été sujet à de nombreux problèmes dans votre Outlook. Afin de les traiter efficacement, vous pouvez aspirer à un moyen polyvalent et puissant. Pourtant, en fait, une telle méthode n'existe pas. Ce que vous pouvez faire, c'est vous méfier de vos propres opérations dans Outlook et effectuer des sauvegardes régulières. Bien sûr, si possible, nous vous suggérons de garder à portée de main un outil de réparation expérimenté, comme DataNumen Outlook Repair. Il peut résoudre divers problèmes PST et réparer PST corrompu déposer comme un jeu d'enfant.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer Sql Server et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com