Sådan eksporteres du hurtigt alle Outlook-mapper og emner i afsnittet "Foretrukne" til en Windows-mappe

Hvis du vil eksportere alle Outlook-mapper samt dets emner i afsnittet "Foretrukne", kan du henvise til denne artikel. Her viser vi dig, hvordan du opnår det hurtigt.

Generelt er mapperne og dens emner i afsnittet "Foretrukne" af stor betydning og ofte nødvendige. Derfor kan du til tider måske eksportere dem til det lokale drev. Som standard skal du oprette Windows-mapper i henhold til mapperne i "Foretrukne" og gemme emner som MSG-filer en efter en i det lokale drev. Det er for kedeligt. Derfor vil vi her udsætte en langt mere effektiv måde. Læs videre for at få det.

Eksporter alle mapper og genstande i afsnittet "Foretrukne" til en Windows-mappe

1. Til at begynde med skal du åbne VBA-editoren i Outlook ved at henvise til “Sådan køres VBA-kode i din Outlook".
2. Kopier derefter følgende kode til et tomt modul.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Klik derefter på ikonet "Kør" i værktøjslinjen.
4. Vælg derefter en Windows-destinationsmappe i pop op-dialogboksen og klik på “OK”.
5. Når makroen er færdig, vises Windows-mappen.
6. I denne Windows-mappe er mapperne og dens emner i afsnittet "Foretrukne" eksporteret, som det følgende skærmbillede.

Gendan Outlook-data fra sikkerhedskopier

Det anbefales stærkt at sikkerhedskopiere Outlook-filer regelmæssigt. Det er fordi, at hvis du lider korruption i Outlook-filer, kan du gendanne Outlook data fra sikkerhedskopier let. Men hvis du ikke har sådan en sikkerhedskopi, skal du forsøge besværlig Outlook-løsning. På det tidspunkt vil reparationsværktøj til indbakke ikke være meget hjælp. Du er nødt til at tage hjælp til at rette eksternt værktøj, såsom DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget sql og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com