Sådan indstilles en anden standardpåmindelsestid for forskellige typer af flagede elementer i din Outlook

Som standard vil Outlook automatisk bruge standardpåmindelsestidspunktet for opgaver til alle slags markerede elementer. Men hvis du gerne vil bruge en anden påmindelsestid for markerede varer på basis af varetype, kan du henvise til metoden introduceret i denne artikel.

Outlook giver dig mulighed for at indstille standard påmindelsestid for alle markerede elementer, uanset varetypen. Du kan gå til menuen "Filer" og klikke på "Indstillinger". Derefter kan du i vinduet "Outlook-indstillinger" se indstillingen "Standard påmindelsestid" på fanen "Opgaver", som vist på det følgende skærmbillede.

Ikke desto mindre håber de fleste brugere at kunne bruge forskellige påmindelsestider for forskellige typer markerede elementer, såsom "9:00" for markerede mails og "17:30" for markerede kontakter. I det følgende vil vi fokusere på dette eksempel for at introducere en metode.

Indstil en anden standard påmindelsestid for forskellige slags mærkede elementer

1. Til at begynde med skal du starte Outlook-applikationen.
2. Gå derefter til Outlook VBA-editor med henvisning til “Sådan køres VBA-kode i din Outlook".
3. I det efterfølgende "Microsoft Visual Basic for Applications"-vindue skal du kopiere følgende kode til "ThisOutlookSession"-projektet.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Genstart derefter Outlook for at aktivere denne makro.
5. Fra nu af, hver gang du markerer en e-mail, vil påmindelsestidspunktet blive sat til "10:00" på flagets forfaldsdato.
6. Og når du markerer en kontakt, vil påmindelsestidspunktet blive sat til "17:30" på flagets forfaldsdato.

Håndter Outlook-problemer fleksibelt

Du kan støde på alle mulige slags problemer i din Outlook. Så du skal lære nogle metoder til at håndtere dem på forhånd. Hvis din Outlook f.eks. ofte genstarter, skal du reparere Office eller deaktivere tredjeparts tilføjelsesprogrammer osv. Eller hvis din Outlook PST bliver kompromitteret, kan du først prøve værktøj til reparation af indbakke. Når det mislykkes, kan du fortsætte med at ty til et kraftfuldt eksternt værktøj, f.eks DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder mdf opsving og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com