Sådan batches åbne alle hyperlinks med et bestemt domæne i din Outlook-e-mail

Når du ser en Outlook-e-mail, som indeholder en masse hyperlinks i brødteksten, vil du til tider kun ønske at hurtigt åbne hyperlinks med et bestemt domæne. Her deler vi en metode til at åbne sådanne hyperlinks i bulk.

I lyset af flere hyperlinks i én e-mail, håber du måske at tjekke nogle af dem i stedet for alle. For eksempel vil du kun gerne batchåbne hyperlinks med et bestemt domæne. Generelt skal du klikke én efter én for at åbne dem. Det er meget besværligt. Derfor vil vi i det følgende lære dig en mere bekvem måde.

Batchåbn alle hyperlinks med et specifikt domæne i e-mail

1. For somtart, få adgang til Outlook VBA-editor i henhold til “Sådan køres VBA-kode i din Outlook".
2. Aktiver derefter referencen til "MS Word Object Lib" i vinduet "Microsoft Visual Basic for Applications"rary ”med henvisning til“Sådan tilføjes et objekt Library Reference i VBA".
3. Kopier derefter følgende VBA-kode til et ubrugt modul eller projekt.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Dernæst tilføj denne makro til værktøjslinjen til hurtig adgang eller båndet.
5. Tag endelig følgende trin for at prøve.

• Først skal du vælge eller åbne en Outlook-e-mail.
• Klik derefter på makroknappen.
• På én gang vil hyperlinks med det foruddefinerede domæne i e-mailen blive batchåbnet i Internet Explorer, som vist på følgende billede:

Slip af med irriterende Outlook-korruption

Selvom Outlook er modtagelig for fejl og korruption, kan du faktisk, så længe du holder øje med alle risici, flygte fra dem med lethed. For eksempel skal du lave sikkerhedskopier af data til Outlook med jævne mellemrum. Desuden bør du passe på de mistænkelige e-mails, som kan indeholde virus. Sidst men ikke mindst må du hellere forberede en Outlook reparation hjælpeprogram, såsom DataNumen Outlook Repair. Det er i stand til at hjælpe dig i tilfælde af Outlook-korruption.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder korrupt SQL Server og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com