Sådan udtrækkes automatisk integrerede billeder fra specifikke indgående e-mails via Outlook VBA

Hvis du vil have Outlook til automatisk at udpakke og gemme de integrerede billeder fra de specifikke indgående e-mails, kan du henvise til denne artikel. Her lærer vi dig, hvordan du realiserer det med VBA-kode.

Nogle brugere har ofte brug for at udtrække de integrerede billeder fra de specifikke indgående e-mails og gemme dem i en bestemt Windows-mappe. Det er så besværligt at manuelt gøre det hver gang. Derfor ser mange frem til at lære en hurtig og bekvem tilgang til at lade Outlook automatisk opnå det. Nu vil vi her dele en sådan metode med dig.

Uddrag automatisk integrerede billeder fra specifikke indgående e-mails

1. For det første skal du starte dit Outlook-program som normalt.
2. Derefter udløser Outlook VBA-editor som normalt med reference t “Sådan køres VBA-kode i din Outlook".
3. Senere skal du kopiere og indsætte følgende VBA-kode i projektet "ThisOutlookSession".

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Klik derefter på underrutinen "Application_Startup".
5. Klik til sidst på "F5" -tasten for at udløse denne makro.
6. Fra nu af, hver gang når en bestemt ny e-mail ankommer til indbakken, gemmes de integrerede billeder i den specifikke Windows-mappe, som vist i det følgende skærmbillede.

Rengør regelmæssigt store tilbehør

Det er tilrådeligt at rydde store vedhæftede filer fra din Outlook regelmæssigt. Dette har til formål at holde din Outlook-fil i den passende størrelse. Større Outlook-filer er mere modtagelige for korruption. Som du ved, er PST-skader ret vanskelige at håndtere ordentligt. Måske vil du først forsøge at reparere dem med et reparationsværktøj til indbakken. Men i de fleste tilfælde vil det ikke virke. Din eneste udvej er en specialiseret PST-reparation værktøj, ligesom DataNumen Outlook Repaireller relevante professionelle genopretningstjenester.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder mdf-rettelse og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com