Sådan får du en meddelelse, hvis du ikke modtager svaret på en bestemt e-mail inden for forventet tid

Outlook-løsninger September 29, 2025

Denne artikel vil lære dig et hurtigt trick ved hjælp af VBA til at lade Outlook automatisk bede dig om at sende en underretnings-e-mail, når du ikke har modtaget svaret fra en bestemt e-mail inden for en bestemt tid.

Til tider for de meget vigtige e-mails vil du helt sikkert se frem til dens svar. Med andre ord skal du håbe, at modtageren kan svare dig hurtigst muligt. Ellers, så længe du endnu ikke har modtaget svaret inden for din forventede tid, sender du en opfølgende e-mail til modtageren igen. Derfor, som svar på dette krav, introducerer vi her en metode, der bruger VBA til at få Outlook til automatisk at advare og bede dig i et sådant tilfælde. Læs videre for at få de detaljerede trin og koder.

Få en meddelelse, hvis du ikke modtager svaret på en bestemt e-mail

Få en meddelelse, hvis du ikke modtager svaret på en bestemt e-mail inden for forventet tid

  1. Fra begyndelsen, start dit Outlook.
  2. Derefter skal du indstille en bestemt påmindelsestid til den specifikke e-mail.
  • For det første skal du højreklikke på den specifikke e-mail.
  • Vælg derefter "Opfølgning"> "Tilføj påmindelse".Føj påmindelse til den specifikke e-mail
  • I dialogboksen kan du indstille påmindelsestiden til det specifikke tidspunkt, inden for hvilket du vil modtage sit svar.Indstil en specifik påmindelse
  1. Derefter skal du trykke på “Alt + F11” -tasten for at få adgang til Outlook VBA-editor.
  2. Næste i det nye vindue skal du åbne projektet “ThisOutlookSession” og kopiere følgende koder ind i det.
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

VBA-koder - Få en meddelelse, hvis du ikke modtager svaret på en bestemt e-mail inden for forventet tid

  1. Underskriv derefter denne kode.
  2. Senere ændre makroindstillingen i Outlook for at tillade digitalt signerede makroer.
  3. Til sidst restart Outlook for at aktivere den nye makro. Fra nu af fungerer Outlook som følger:
  • Hvis du har modtaget svaret fra den specifikke e-mail, før påmindelsen dukker op, rydder Outlook automatisk flag og deaktiver påmindelsen.
  • Hvis du ikke har modtaget svaret, når påmindelsen udløses, vil Outlook bede dig om at sende en opfølgende e-mail. Hvis du vælger “Ja”, sendes e-mailen. Hvis du vælger “Nej”, forsvinder prompten med det samme.

Løs irriterende Outlook-problemer

Da Outlook er udsat for fejl for at forhindre Outlook korruption, du må hellere ikke kun stole på indbakkeværktøjet, Scanpst.exe. Du skal forberede et andet potent og velrenommeret reparationsværktøj, såsom DataNumen Outlook Repair, som kan bortskaffe de irriterende problemer, som Scanpst.exe ikke kan løse.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql korruption og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.