Sådan batch slettes alle læsekvitteringer i din Outlook

For at bekræfte, at modtagerne har læst din e-mail, kan du anmode om en læsekvittering, når du skriver e-mailen. I denne situation kan din postkasse være fyldt med sådanne læsekvitteringer. I dette indlæg lærer du, hvordan du sletter dem permanent i store mængder.

Efter at have læst artiklen “Sådan batch slettes alle leveringskvitteringer i din Outlook“, Kan du tænke over tilgangen til massesletning af alle læsekvitteringer. Faktisk er den åbenlyse forskel mellem de to slags kvitteringer deres emner. Leveringskvittering indeholder "Leveret" i emne, men læsekvittering indeholder "Læs" i stedet. Derfor kan du bruge samme måde til batch-sletning af alle læsekvitteringer. I det følgende vil vi lære dig de konkrete trin i detaljer.

Batch Slet alle læse kvitteringer

1. Start din Outlook fra starten.
2. Gå derefter til Outlook VBA-editor via "Alt + F11" i henhold til "Sådan køres VBA-kode i din Outlook".
3. Derefter skal du åbne et tomt modul i det nye vindue og sætte følgende kode i det.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Klik derefter på den første underrutine.
5. Til sidst skal du trykke på “F5” -tasten.
6. På en gang vil makroen arbejde på at slette alle læsekvitteringer fra din Outlook.
7. Når det er færdigt, får du en prompt om resultatet, som skærmbilledet nedenfor.
8. På nuværende tidspunkt kan du kontrollere dine mailmapper. Alle læse kvitteringer er væk.

Forsvar Outlook-data

Selvom Outlook-filen ganske vist er modtagelig for korruption, kan vi tage skridt til at beskytte den. For eksempel skal vi holde Outlook-filen i lille størrelse, beskytte den mod ondsindede faktorer og sikkerhedskopiere den regelmæssigt. Sidst men ikke mindst, skal du hellere forberede et potent eksternt PST-reparationsværktøj, som f.eks DataNumen Outlook Repair. Det vil have stor indvirkning på reparationen korrupt Outlook fil.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql reparation og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com