Sådan indstilles Outlook automatisk online eller offline baseret på dine arbejdstider

Outlook-løsninger September 29, 2025

Nogle brugere vil gerne få Outlook til automatisk at skifte mellem online og offline status baseret på deres arbejdstid. Så i denne artikel deler vi en hurtig metode med dig.

Faktisk er det meget nemt at indstille Outlook online eller offline. For at gøre Outlook til offline-status kan du bare skifte til “Send / modtag” -fanen og trykke på knappen “Arbejd offline”. Og for at vende tilbage til online status skal du blot trykke på denne knap igen. Nogle brugere håber dog, at Outlook automatisk kan skifte til offline-status, når det er ude af arbejdstid og vende tilbage til online i arbejdstid. Selvom Outlook ikke indeholder en sådan funktion, kan du stadig bruge følgende VBA-kode til at opnå det.

Indstil Outlook automatisk eller offline baseret på dine arbejdstider

Indstil Outlook automatisk eller offline baseret på dine arbejdstider

  1. Start din Outlook-applikation helt fra starten.
  2. Derefter, efter at have fået adgang til din Outlook, skal du åbne din Tasks-mappe.
  3. Dernæst skal du oprette et dagligt tilbagevendende opgaveelement.
  • Klik på knappen "Ny opgave" i båndet.
  • Indtast derefter “Offline” i opgavens emnelinje.
  • Klik derefter på knappen "Gentagelse" under fanen "Opgave".
  • I pop op-dialogboksen skal du vælge "Dagligt" gentagelsesmønster, aktivere "Ingen slutdato" og trykke på "OK".Opret et dagligt tilbagevendende opgaveelement
  • Dernæst skal du aktivere en påmindelse kl. 5:00.Aktivér en påmindelse kl. 5:00
  • Til sidst skal du trykke på knappen "Gem og luk".
  1. Derefter skal du oprette en anden daglig tilbagevendende opgave kaldet "Online" og aktivere en påmindelse "8:00", vist som billedet nedenfor:Opret en anden daglig tilbagevendende opgave kaldet “Online”
  2. Derefter skal du trykke på “Alt + F11” -tasten i hovedvinduet i Outlook.
  3. Dernæst får du adgang til Outlook VBA-editor, hvor du skal finde og åbne projektet "ThisOutlookSession".
  4. Senere kopieres følgende VBA-kode til dette projekt.
Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

VBA-kode - Indstil automatisk Outlook online eller offline baseret på dine arbejdstider

  1. Til sidst kan du genstarte Outlook for at aktivere denne makro.
  2. Fra nu af vil din Outlook være online i arbejdstid og automatisk skifte til offline-status uden for arbejdstid.

Din sidste udvej i tilfælde af Outlook-nedbrud

Selvom Outlook kan prale af flere funktioner, kan Outlook stadig ikke holde sig væk fra fejl og skader. Men tag ikke panik. Så længe du træffer tilstrækkelige forholdsregler, kan du stadig beskytte dine Outlook-data effektivt. For eksempel skal du sikkerhedskopiere dine PST-filer regelmæssigt, da sikkerhedskopier giver dig mulighed for at komme tilbage korrupt PST data. Også at holde et kraftfuldt reparationsværktøj, ligesom DataNumen Outlook Repair, er også et spørgsmål om nødvendighed.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder rette mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.