3 metoder til at importere e-mails fra en Windows-mappe til din Outlook

Måske har du gemt flere Outlook-e-mails i din Windows-mappe. Nu, hvis du vil importere dem tilbage til en Outlook-mappe, hvordan kan du så gøre det? Denne artikel vil lære dig 3 måder.

Som vi alle ved, giver Outlook en indbygget mulighed - "Gem som", hvorved du kan gemme e-mails i Windows-mappen. Der er dog ingen funktion for dig at tilføje de eksporterede e-mails tilbage til Outlook-mappen. Derfor, hvis du gerne vil importere Outlook-e-mails tilbage til Outlook, hvordan kan du så realisere det? I det følgende vil vi lære dig 3 metoder. Du kan vælge hvilken som helst efter dine præferencer.

Metode 1: Træk og slip for at importere

1. Allerede fra starten skal du have adgang til Windows-kildemappen, som gemmer de Outlook-e-mails, der skal importeres til Outlook.
2. Start derefter din Outlook-applikation.
3. Åbn derefter Outlook-mappen, som du vil importere e-mails til.
4. Efterfølgende skal du indsnævre både Windows-mappevinduet og Outlook-vinduet, indtil du kan se dem i mellemtiden.
5. Derefter kan du i Windows-mappen vælge en af ​​Outlook-e-mails og derefter trykke på "Ctrl + A" for at vælge dem alle.
6. Senere kan du trække og slippe de valgte e-mails til den synlige Outlook-mappe, som følgende skærmbillede:
7. Endelig vil du se, at alle Outlook-e-mails er blevet importeret fra Windows-mappen til Outlook-mappen, vist som billedet nedenfor:

Metode 2: Brug "CreateItemFromTemplate" i VBA

1. Til at starte med skal du trykke på tasterne “Alt + F11” i hovedvinduet i Outlook.
2. Dernæst får du adgang til Outlook VBA editor-vinduet.
3. Kopier derefter følgende VBA-kode til et tomt modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Dernæst kan du trykke på F5-tasten i det aktuelle modulvindue for at starte makroen.
5. Derefter skal du gå til kilden til Windows-mappen i pop op-dialogboksen.
6. Til sidst, efter valg af kildemappe, importeres alle Outlook-emner i den mappe til den foruddefinerede Outlook-mappe.
7. Bemærk: på denne måde er de importerede e-mails alle friske nye e-mails, som du kan skrive efter behag, som følgende skærmbillede:

Metode 3: Brug "OpenSharedItem" i VBA

1. Ligesom metode 2 skal du kopiere følgende VBA-koder til et andet modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Kør derefter denne makro ved at trykke på "F5"-tasten.
3. Vælg derefter kildemappen.
4. Til sidst vil alle e-mails blive importeret som billedet nedenfor:

Sammenligninger

Midler til at blokere PST-datakorruption

Som vi alle ved, leveres Outlook forudinstalleret med et indbygget værktøj - scanpstDet meste af tiden er det i stand til at løse små problemer. Men hvis problemerne er voldsomt alvorlige, vil det indbyggede værktøj have en tendens til at fejle. Så du bør vende tilbage til et mere effektivt værktøj, som f.eks. DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder SQL Server korruption og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com