2 måder at udskrive listerne over Outlook-opgaver med forskellige kategorier på forskellige sider

Hvis du har tildelt forskellige farvekategorier til dine Outlook-opgaver og nu vil udskrive lister over opgaver med forskellige kategorier på forskellige sider, kan du henvise til denne artikel. Her deler vi dig 2 metoder til at få det.

For at klassificere og administrere dine opgaver godt har du måske anvendt farvekategorier på dine opgaver. Hvis du nu vil udskrive listerne over dine opgaver med forskellige kategorier på forskellige sider, skal du læse videre. I det følgende vil vi introducere dig to måder at få det på.

Metode 1: Udskriv opgavelister manuelt en efter en

1. Først og fremmest skal du åbne ruden "Opgaver" i Outlook.
2. Åbn derefter en opgavemappe.
3. Tryk derefter på "Ctrl + E" for at aktivere "Søg" -båndet.
4. Klik derefter på "Kategoriser" -knappen under fanen "Søg".
5. Vælg en farvekategori på rullelisten.
6. Derefter er kun opgaverne med den valgte kategori tilbage på listen.
7. Gå nu til "File"> "Print" for at udskrive denne opgaveliste.
8. Derefter udskriver lister over opgaver med de andre farvekategorier manuelt manuelt på samme måde.

Metode 2: Batch-udskriv opgavelisterne fra VBA

1. Start VBA-editoren i starten i overensstemmelse med “Sådan køres VBA-kode i din Outlook".
2. Tilføj derefter referencen til "MS Excel Object Library" som angivet i "Sådan tilføjer du en objektbiblioteksreference i VBA".
3. Kopier derefter følgende VBA-kode til et modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Tryk derefter på "F5" -tasten for at køre denne makro med det samme.
5. Når makroen er færdig, udskrives listerne over opgaver med forskellige kategorier på forskellige sider som vist i det følgende skærmbillede.

Få værdifulde data tilbage fra kompromitteret PST-fil

Hvis du er underlagt en utilgængelig PST-fil, er dit næste trin utvivlsomt PST-reparation. I dette tilfælde kan du først prøve reparationsværktøjet til indbakken. Forudsat at det mislykkes, kan du fortsætte med at prøve et andet eksternt værktøj, f.eks DataNumen Outlook Repair. Det er i stand til at gendanne PST-data på hurtig tid.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder gendanne mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com