2 metoder til hurtigt at tælle e-mails efter afsender i din Outlook

Outlook-løsninger September 29, 2025

Hvis du gerne vil tælle e-mails efter afsender, kan du henvise til denne artikel. Her vil vi afsløre 2 hurtige tilgange til dig.

For at finde ud af, hvem der er mest aktiv for dig, kan du tælle e-mails efter afsender. Selvom Outlook ikke tilbyder en direkte funktion til dette, kan du stadig finde nogle løsninger, såsom metode 1. Hvis du synes, at metode 1 er for besværlig, kan du vælge metode 2. Den er meget mere effektiv, fordi den bruger VBA til hurtigt at tælle e-mails efter afsender og eksportere antallet til Excel. Læs nu videre til de to metoder i detaljer. Her tager vi e-mails i Indbakken som et eksempel.

Metode 1: Få tællinger efter gruppering af elementer efter "Fra"-felt

  1. Start med at starte Outlook-applikationen.
  2. Åbn derefter indbakkemappen.
  3. Skift derefter til fanen "Vis".
  4. Vælg derefter "Fra" i gruppen "Arrangement".Arranger indbakkeelementer efter "Fra"
  5. På én gang er alle indbakkeposter blevet opdelt i forskellige grupper i henhold til de forskellige afsendere.
  6. Nu, for at tælle elementerne fra en bestemt afsender, kan du vælge alle elementer i den relaterede gruppe og trykke på "Enter"-tasten. I popup-advarslen kan du se optællingen.Få vareantal i Advarsel

Det betyder, at det er ret nemt, men vareantallet inkluderer faktisk de andre typer elementer, såsom mødeinvitationer, opgaveanmodninger og kvitteringer, ikke kun e-mail-tæller. Hvis du således kun vil tælle e-mails, kan du i stedet bruge følgende måde.

Metode 2: Tæl e-mails af afsender med Outlook VBA

  1. Til at starte med skal du trykke på "Alt + F11"-tasterne i Outlook.
  2. Aktivér derefter "MS Excel Object Library" i henhold til "Sådan tilføjer du en objektbiblioteksreference i VBA".
  3. Kopier derefter koden nedenfor til et ubrugt modul.
Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

VBA-kode - Tæl indbakke-e-mails af afsender

  1. Derefter skal du trykke på “F5” -tasten.
  2. Når makroen er færdig, vil en ny Excel-fil blive vist.
  3. Som du kan se, indeholder den antallet af indbakke-e-mails fra forskellige afsendere.E-mail tæller i Excel

Bortskaf frustrerende Outlook-problemer

Måske har du nogensinde været udsat for mange problemer i din Outlook. For at løse dem effektivt, kan du længes efter en alsidig og mægtig måde. Alligevel er der faktisk ikke en sådan metode. Hvad du kan gøre er at passe på dine egne operationer i Outlook og lave regelmæssige sikkerhedskopier. Selvfølgelig, hvis det er muligt, foreslår vi, at du hellere må have et erfarent fixværktøj ved hånden, f.eks DataNumen Outlook Repair. Det kan løse forskellige PST-problemer og reparere korrupt PST fil som en leg.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder genvinde Sql Server og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.