Как бързо да отпечатате всички прикачени изображения на имейл на Outlook само на една страница

За да спестят мастило и хартия на принтера, някои потребители искат да отпечатат всички изображения, прикачени в имейл, само на една страница, вместо по едно изображение на страница. Сега тази статия ще сподели начин да я реализирате.

Както всички знаем, отпечатването на изображения е доста загуба на мастило на принтера. По този начин, за да спестите мастило и хартия на принтера, може би предпочитате да отпечатвате много прикачени изображения на една и съща страница, вместо да отпечатвате изображения на отделни страници. Въпреки че Outlook не предлага такава функция, все пак можете да я постигнете по следните начини.

Отпечатайте всички прикачени изображения на имейл на Outlook само на една страница

1. За начало стартирайте приложението си Outlook.
2. След това в прозореца на Outlook докоснете бутоните „Alt + F11“.
3. След това ще влезете в прозореца „Microsoft Visual Basic for Applications“, в който първо трябва да активирате „Microsoft Word Object Library“.
4. След това трябва да отворите модул, който не се използва.
5. Впоследствие копирайте и поставете следния VBA код в този модул.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. По-късно можете да се върнете към имейл списъка. Изберете или отворете имейл, чиито прикачени снимки искате да разпечатате.
7. След това задействайте този макрос. В текущия прозорец на макроса просто натиснете клавиша „F5“ или щракнете върху иконата „Изпълни“ в лентата с инструменти.
8. И накрая, когато макросът приключи, всички прикачени изображения на имейл източника ще бъдат разпечатани на една страница, като следната екранна снимка:

Справете се с повредени файлове на Outlook

С все повече и повече данни, съхранявани във вашия Outlook, вашият файл на Outlook става все по-уязвим. Той може да бъде компрометиран поради различни вътрешни и външни фактори. Също така е трудно да се предвиди корупцията в Outlook. И така, това, което можете да направите, е да осигурите незабавно и ефективно спасяване при среща с корупцията на Outlook. Например, трябва да поддържате специализиран PST ремонт инструмент, като DataNumen Outlook Repair в близост. Той ще сканира и възстанови повредени файлове като бриз.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително възстановяване Sql Server и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com