Как бързо да експортирате папка на Outlook с всички подпапки и елементи в папка на Windows

Понякога може да искате да експортирате групово папка на Outlook с всички подпапки и елементи в папка на Windows. Тази статия ще ви научи на такъв метод, който прилага Outlook VBA.

Когато искате да експортирате папка на Outlook на локално устройство с всички елементи в една и съща структура на папката, ако изберете да запазвате и експортирате ръчно, ще ви отнеме много време. Следователно, защо не прибягвате до други средства, като инструменти за износ или кодове на VBA? Тук ще ви разкрием такава част от кода на VBA. Това ще ви позволи да го постигнете като бриз.

Експортирайте всички подпапки и елементи в папка на Outlook в папка на Windows

1. В самото начало стартирайте програмата си Outlook.
2. След това в главния прозорец на Outlook натиснете клавишните комбинации „Alt + F11“.
3. Впоследствие ще се появи прозорецът „Microsoft Visual Basic for Applications“.
4. След това трябва да отворите празен модул и да копирате следните VBA кодове в него.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. След това трябва да се уверите, че вашият Outlook разрешава макроси в настройките на макроса.
6. В крайна сметка можете да опитате.

• Първо, обратно към новия прозорец на макроса.
• След това кликнете върху подпрограмата „ExportFolderWithAllItems“.
• След това натиснете бутона F5, за да стартирате този макрос.
• След това трябва да изберете конкретна папка.
• И накрая, когато получите съобщение с надпис „Complete“, можете да получите достъп до предварително дефинираната локална папка. Ще откриете, че всички елементи са запазени в една и съща структура на папката.

Предотвратяване на загуба на данни от сривове в Outlook

Вероятно някога сте се сблъсквали с много сривове на Outlook. В повечето случаи, след рестартиране, Outlook ще може да работи нормално. Съществува обаче и случай, че нашият PST файл може да се повреди. В този случай ще се опитате да възстановите PST данните си, като например се обърнете към опитен инструмент като DataNumen Outlook Repair, Той е в състояние да поправете Outlook грешки и извличане на данни от компрометиран PST файл, без да се поти пот.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server ремонт и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com