Как бързо да експортирате информацията за размера на всички папки в PST файл във файл на Excel

Решения за Outlook Септември 29, 2025

Ако искате да проверите информацията за размера на всяка папка в PST файл, можете да използвате метода, изложен в тази статия. Той бързо ще експортира информацията за размера на всички папки в PST файл в файл на Excel.

Когато вашият PST файл е твърде голям, може да пожелаете да проверите размера на всяка папка. Това ще ви помогне лесно да разберете кои са по-големите и да направите подходящо архивиране въз основа на размера. Като цяло, за да проверите размера на папката, можете просто да щракнете с десния бутон върху папка и след това да изберете “Properties”. В новия изскачащ диалогов прозорец можете да щракнете върху бутона „Размер на папката“. Ако обаче сте създали много папки, ръчната проверка на информацията за размера една по една е значително обезпокоителна. Така че, ако искате групово да получите информация за размера на всички папки в PST файл, можете да използвате следния VBA код. Той едновременно ще експортира всички имена на папки и информация за размера в файл на Excel.

Експортирайте информацията за размера на всички папки в PST файл във файл на Excel

За начало стартирайте приложението си Outlook.
След това преминете към раздела „Разработчик“ и щракнете върху бутона „Visual Basic“ или натиснете клавишите „Alt + F11“ за достъп до редактора на VBA.
След това в прозореца „Microsoft Visual Basic for Applications“ отворете модул, който не се използва.
След това копирайте и поставете следните VBA кодове в този модул.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

След това трябва да зададете нивото на защита на вашия макрос на Outlook на ниско.
В крайна сметка можете да опитате.

Натиснете бутона F5 в текущия прозорец на макроса.
След това ще бъдете помолени да изберете PST файл, като следното изображение:
След като избере изходен файл, Outlook ще започне да експортира информация за размера в Excel.
След завършване на макроса получавате съобщение като екранната снимка по-долу.
И накрая, ще можете да намерите файла на Excel в предварително дефинираната локална папка. Файлът на Excel ще изглежда по следния начин:

Справете се с честите PST грешки

Тъй като Outlook е склонен към грешки, може би някога сте страдали от много проблеми във вашия Outlook. За да се справите по-добре и по-гъвкаво с разочароващите проблеми с PST, препоръчително е да държите в близост опитна и реномирана помощна програма за коригиране, като DataNumen Outlook Repair, Той е в състояние да коригирайте PST проблеми като бриз.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com