Как бързо да копирате структурата на папките от един PST файл на Outlook в друг чрез VBA

Ако искате да копирате структурата на папките от един PST файл на Outlook в друг, можете да използвате метода, представен в тази статия, който ще ви научи как да използвате VBA, за да го получите наведнъж.

Може би, за да управлявате по-добре имейлите си, сте създали няколко персонализирани папки в основния си файл на Outlook. По този начин, когато създавате нов PST файл на Outlook, може да искате да приложите същата структура на папките. Всъщност в предишната ми статия – „2 стъпки за запазване на текущата йерархия на папките в нов файл на Outlook”, можете да научите традиционен метод, който използва функцията „Архивиране”, за да го постигне. Въпреки това всъщност все още е малко досадно. В сравнение с него използването на VBA кодове за получаването му ще бъде много по-бързо. Ето защо по-долу ще ви кажем сложните стъпки и кодове.

Копирайте структурата на папките от един PST файл на Outlook в друг

1. В самото начало стартирайте програмата си Outlook.
2. След това в прозореца на Outlook натиснете бутоните „Alt + F11“.
3. След това ще влезете в прозореца на редактора на Outlook VBA.
4. След това копирайте и поставете следните VBA кодове в нов модул.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. След това променете нивото на защита на макроси на ниско.
6. По-късно се върнете към прозореца на редактора на VBA и натиснете бутона „F5“, за да стартирате макроса.
7. Накрая, след като макросът приключи работа, ще получите съобщение, подканващо „Завършено!“.
8. В този момент можете да отидете до навигационния панел на пощата. Ще видите нов файл с данни на Outlook, който е в същата структура на папките като изходния PST файл, като изображението по-долу:

Справете се с отчайващите PST проблеми

Тъй като Outlook PST е податлив на грешки, много от вас трябва да са се сблъсквали с различни проблеми в Outlook. Изправени пред тях, можете първо да използвате инструмента за поправка на входящата кутия на Outlook, за да опитате. Ако не успее, можете да приложите по-мощен инструмент на трета страна, като напр DataNumen Outlook Repair, който може поправете Outlook PST грешки като полъх.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server фиксира и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com