Как бързо да извлечете всички получатели от множество файлове с съобщения в Outlook (.msg)

Някои потребители биха искали бързо да извлекат всички получатели от множество файлове за съобщения на Outlook, запазени от имейли на Outlook. Сега, този стрost ще разгледаме това, за да споделим бърз подход.

За да извлечете получателите от един файл на съобщение на Outlook, можете просто да щракнете двукратно, за да го отворите и след това да копирате получателите в отворения прозорец на съобщението. Но ако трябва да се справите с група от файлове със съобщения в Outlook, ръчният метод не е достатъчно ефективен. По този начин може да потърсите много по-ефективен начин. Тук ще ви представим такъв. Прочетете, за да получите подробности.

Извличане на всички получатели от множество файлове с съобщения в Outlook (.msg)

1. За катоtart, получете достъп до редактора на Outlook VBA според „Как да стартирате VBA код във вашия Outlook".
2. След това копирайте и поставете следния VBA код в празен модул.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. След това преместете курсора в първата подпрограма.
4. След това щракнете върху бутона „Run“ или натиснете клавиша „F5“.
5. След това в изскачащия диалогов прозорец изберете папката на Windows, която съдържа изходните файлове на съобщението на Outlook (.msg).
6. След като изберете, щракнете върху „OK“, за да позволите на макроса да продължи да работи.
7. Когато макросът завърши, ще се покаже съобщение, съдържащо всички имейл адреси на извлечените получатели, както е показано на следващата екранна снимка.

Защитете данните си от Outlook от опасност

Данните в Outlook са склонни към корупция. Следователно е доста сложна задача да се защитят данните на Outlook. Това изисква от вас да настоявате да правите редовно архивиране на данни на Outlook. Също така, ако е възможно, е разумно и препоръчително да се подготви опитен и професионален Outlook PST ремонт инструмент, като DataNumen Outlook Repair, за да можете да получите незабавно и навременно спасяване в случай на корупция в Outlook.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително възстановяване Sql Server и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com