Как бързо да създадете група контакти от всички контакти на Outlook с конкретно заглавие на длъжността

За да комуникирате по-лесно с контактите с конкретна длъжност, може да искате бързо да създадете група от контакти от тези контакти. Сега в тази статия ще споделим бърз метод с вас.

Ако често изпращате групово имейли, задачи или покани за събрания до контактите с конкретно заглавие, ще бъде много по-удобно, ако създадете група от контакти от тях. Като цяло, по стандартния начин, първо трябва да създадете нова група контакти и след това да добавите контакти към групата като членове един по един. Това е малко обезпокоително. Следователно в следващите неща ще ви научим на много по-бърз начин да го получите.

Създайте група контакти от Всички контакти със специфично заглавие на длъжността

1. Отначало в папка Контакти изберете контакт, който има конкретното заглавие.
2. След това натиснете „Alt + F11“ за достъп до редактора на Outlook VBA.
3. След това копирайте следния VBA код в празен модул или проект.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. След това преместете курсора в първата подпрограма.
5. Накрая натиснете бутона „F5“, за да стартирате този макрос.
6. Когато макросът завърши, ще се покаже нова група контакти. Той съдържа всички контакти с едно и също заглавие на избрания контакт в стъпка 1.

Shield Outlook данни ефективно

Въпреки че Outlook е богат на функции, той не може да се отърве от факта, че е уязвим. Така че, ако не искате да загубите ценните си данни от Outlook, трябва да положите усилия да ги защитите. Например трябва да правите резервни копия на данни на Outlook на редовни интервали. Също така, ако е на достъпна цена, се препоръчва да имате авангарден инструмент за ремонт на PST, като например DataNumen Outlook Repair, който може ремонт PST данни за миг.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден sql и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com