Ако искате бързо да експортирате структурата на папките на вашия файл с данни на Outlook в работна книга на Excel, можете да използвате метода, представен в тази статия.
По някои причини, като регистриране на текущи папки и подпапки на Outlook, много потребители се надяват да експортират структурата на папките на файл на Outlook във външен файл, като работна книга на Excel. По-нататък ще ви споделим част от кода на VBA, която може да ви помогне да го постигнете за миг.
Експортирайте структурата на папките на вашия файл на Outlook в Excel
- За начало стартирайте приложението си Outlook.
- След това, в главния прозорец на Outlook, натиснете бутоните „Alt + F11“.
- След това ще влезете в редактора на Outlook VBA, в който трябва да отворите неизползван модул.
- Впоследствие можете да копирате следния VBA код в този модул.
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long
Sub ExportFolderStructureToExcel()
Dim objSourcePSTFile As Folder
'Add a new Excel workbook
Set objExcelApp = CreateObject("Excel.Application")
Set objExcelWorkbook = objExcelApp.Workbooks.Add
Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
With objExcelWorksheet
.Cells(1, 1) = "Folder Structure"
.Cells(1, 1).Font.Size = 14
.Cells(1, 1).Font.Bold = True
End With
'Select an Outlook PST file
Set objSourcePSTFile = Application.Session.PickFolder
lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
Call ProcessFolders(objSourcePSTFile.Folders)
'Save this Excel workbook
objExcelWorksheet.Columns("A").AutoFit
strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
objExcelWorkbook.Close True, strExcelFile
MsgBox "Complete!", vbExclamation
End Sub
Sub ProcessFolders(ByVal objFolders As Folders)
Dim objFolder As Folder
'Process all folders recursively
For Each objFolder In objFolders
If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
Call ProcessFolders(objFolder.Folders)
End If
Next
End Sub
Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
Dim i, n As Long
Dim strPrefix As String
Dim nLastRow As Integer
i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
For n = lMainFolder To i
strPrefix = strPrefix & "-"
Next
strFolderName = strPrefix & strFolderName
'Input the folder name in Excel
nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub
- След това трябва да се уверите, че Outlook е активирал макроси.
- В крайна сметка можете да направите снимка:
- В текущия прозорец на макроса натиснете бутона F5.
- След като макросът завърши, ще получите предупреждение с подкана „Завършено“.
- По-късно можете да се насочите към предварително дефинираната локална папка, за да намерите нов файл на Excel. Отворете го и ще изглежда като следната екранна снимка:
Никога не пренебрегвайте грешки в Outlook
Въпреки многото възможности, Outlook е същият податлив на грешки и корупция като другите имейл клиенти. Следователно трябва да придавате значение на всички грешки във вашия Outlook. Не ги пренебрегвайте, моля. В противен случай натрупването на грешки може окончателно да доведе до корупция в Outlook. Ако се сблъскате с възли на грешки, се препоръчва да използвате мощен инструмент, като например DataNumen Outlook Repair, който може ремонт на Outlook грешки в рамките на секунди.
Въведение на автора:
Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително sql възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com