Как да групово запазване на множество чернови имейли като шаблони на Outlook

Може би сте създали няколко чернови имейла и се надявате да ги използвате повторно много пъти. Ако е така, защо не ги запазите групово като шаблони на Outlook? Тази статия ще ви научи да го постигате с едно движение чрез VBA.

По подразбиране Outlook позволява на потребителите да записват наведнъж само един имейл като шаблон. С други думи, не можете да записвате множество чернови имейли като шаблони в насипно състояние. Както виждате, когато изберете повече от една поща и отидете на „Файл“> „Запазване като“, не можете да намерите формата „Шаблон на Outlook“ в списъка „Запазване като тип“, наличен е само „Текст“. Но ние ще ви представим как да го реализирате в по-голямата си част в следващите.

Пакетно запазване на множество чернови имейли като шаблони на Outlook

1. В самото начало задействайте редактора на Outlook VBA.
2. В новия прозорец „Microsoft Visual Basic for Applications“ копирайте и поставете VBA кода по-долу.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. След това, за по-късно удобство, се препоръчва да прикачите този макрос към лентата с инструменти за бърз достъп (QAT). За подробни стъпки можете да прочетете „Как да стартирате VBA код във вашия Outlook"
4. В крайна сметка можете да направите снимка, като следвате операциите по-долу.

• Отначало изберете черновите на имейли, които да бъдат запазени като шаблони.
• След това щракнете върху бутона за макрос в QAT.
• Когато макросът завърши, ще се покаже папката Windows за запазване на шаблоните по подразбиране на Outlook. Можете да видите, че шаблоните от избраните чернови на имейли са там.

Инструментът за поправка на входящата поща все още може да се провали

Що се отнася до вътрешния инструмент за корекция на Outlook - Scanpst, голям брой потребители ще го оценят. Несъмнено тази програма наистина е в състояние да разреши повечето малки проблеми в Outlook. И все пак не е напълно безупречно. Все още може да се провали и да доведе до много грешки. Например в случай на тежки Корупция в Outlook, той не е в състояние да поправи компрометирания PST файл. В този сценарий нямате алтернатива, освен да използвате по-могъщ инструмент с трета страна, като напр. DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително sql възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com