Как да групирате вмъкване на множество снимки във вашия Word документ

В тази статия бихме искали да ви предложим начина за групово вмъкване на множество снимки във вашия документ на Word.

Можете да се чувствате комфортно, докато работите със снимки в Word. След като вмъкнете снимка в документ, може да се наложи да я преоразмерите ръчно или да въведете името й наоколо. Какво ще кажете за използване на макрос за автоматично изпълнение на задачата?

Макросът, който ще ви представим, може да изпълнява следните функции:

1. Първо, той вмъква точен брой снимки, които сте посочили във всяка страница.
2. На второ място, той вмъква името под всяка снимка.
3. На трето място, той преоразмерява картините според номерата на размера, които въвеждате.

Сега нека разгледаме как го караме да работи.

Партидно вмъкване на множество снимки в документ

1. На първо място, подредете всички снимки да бъдат вмъкнати в една и съща папка.
2. След това натиснете „Alt + F11“, за да извикате редактора на VBA в Word.
3. След това щракнете върху „Нормален“ проект.
4. След това в лентата с менюта кликнете върху „Вмъкване“.
5. И от падащото меню изберете „Модул“.
6. Отворете модула чрез двукратно щракване и поставете следните кодове:

Sub InsertSpecificNumberOfPictureForEachPage()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim objInlineShape As InlineShape
  Dim nResponse As Integer
  Dim strPictureNumber As Integer
  Dim strPictureSize As String
  Dim n As Integer  

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
  
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With

  strFile = Dir(StrFolder & "*.*", vbNormal)
  strPictureNumber = InputBox("Input the number of the picture for each page", "Picture Number", "For exemple: 1")
  n = 1  

  While strFile <> ""
    Selection.InlineShapes.AddPicture FileName:=StrFolder & strFile, LinkToFile:=False, SaveWithDocument:=True
    Selection.TypeParagraph
    Selection.Collapse Direction:=wdCollapsEnd
    Selection.TypeText Text:=Left(strFile, InStrRev(strFile, ".") - 1)
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    If ActiveDocument.InlineShapes.Count = strPictureNumber * n Then
      Selection.InsertNewPage
      Selection.TypeBackspace
      n = n + 1
    End If
    Selection.TypeParagraph
    strFile = Dir()
  Wend

  For Each objInlineShape In ActiveDocument.InlineShapes
    objInlineShape.Select
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
  Next objInlineShape

  nResponse = MsgBox("Do you want to resize all pictures?", 4, "Resize Picture")
  If nResponse = 6 Then
    strPictureSize = InputBox("Input the height and width of the picture, seperated by comma", "Height and Width", "For exemple:500,500")
    For Each objInlineShape In ActiveDocument.InlineShapes
      objInlineShape.Height = Split(strPictureSize, ",")(0)
      objInlineShape.Width = Split(strPictureSize, ",")(1)
    Next objInlineShape
  End If
End Sub

7. След това щракнете върху „Run“ или натиснете „F5“.
8. Докато стартирате макроса, ще се появи прозорецът „Преглед“. Просто изберете папката, в която съхранявате снимки в стъпка 1 и щракнете върху „OK“.
9. След това в полето „Номер на картината“ въведете число, представляващо общия брой снимки, които искате в една страница. И щракнете върху „OK“, за да продължите.
10. В полето „Преоразмеряване на картината“ щракнете върху „Да“, за да преоразмерите всички снимки, и върху „Не“, за да го отмените.
11. Сега в полето „Височина и ширина“ въведете стойности и използвайте запетая за разделяне. Не забравяйте първо да въведете височина и след това ширината. Няма място след запетая.
12. По същия начин щракнете върху „OK“, за да продължите напред.

Сега има 2 снимки на една страница и всяка има своето име под нея. Ето резултата:

Следете целостта на данните

Винаги съществува риск да загубите данни или да ги компрометирате по някакъв начин. Това означава, че трябва редовно да проверяваме целостта на данните. И след като намерим някакви признаци на Увреждане на думите, най-добрият начин за възстановяване на данни е да получите инструмент за поправка.

Въведение на автора:

Вера Чен е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително Възстановяване на Excel и pdf ремонт на софтуерни продукти. За повече информация посетете WWW.datanumen.com