Как да експортирате автоматично информация за входящи имейли във файл на Excel с Outlook VBA

Много потребители се надяват, че Outlook може автоматично да експортира основната информация за входящи имейли във файл на Excel. Тази статия ще разгледа това изискване и ще представи бърз метод чрез Outlook VBA.

Понякога по някакви причини, като статистика за пощата, може често да се налага да експортирате имейлите във файл на Excel. Като цяло за съществуващите получени имейли можете просто да използвате функцията „Импортиране и експортиране“, за да ги експортирате в Excel наведнъж. Въпреки това може би дори желаете Outlook да може автоматично да експортира входящите имейли в Excel веднага щом пристигнат във вашата пощенска кутия. Без съмнение няма такава родна функция в Outlook. Следователно трябва да използвате други подходи, като добавка на трета страна или Outlook VBA. Тук ще ви научим как да го направите автоматизиран с Outlook VBA. Прочетете, за да получите стъпките и съответните кодове.

Автоматично експортиране на информация за входящи имейли във файл на Excel

1. На първо място, трябва да създадете Excel файл.

• Отворете нов файл на Excel.
• След това трябва да въведете „Не“. в клетка A1, „Име на изпращача“ в клетка B1, „Имейл адрес на изпращача“ в клетка C1 и „Тема на имейл“ в клетка D1 и „Време на получаване“ в клетка E1, като следното изображение.
• Накрая го запазете в желаното от вас име и желаната папка.

2. След това трябва да стартирате Outlook.
3. След това натиснете клавишните бутони „Alt + F11“, които ще ви отведат до редактора на VBA.
4. След това в изскачащия прозорец трябва да щракнете два пъти върху „ThisOutlookSession“ от лявата страна.
5. Впоследствие в прозореца на проекта „ThisOutlookSession“ трябва да копирате и поставите следните VBA кодове в него.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. По-късно трябва да подпишете този код.
7. Впоследствие, решtart Outlook, за да активирате новия VBA проект.
8. В крайна сметка отсега нататък всички входящи имейли ще бъдат автоматично експортирани в предварително зададения файл на Excel веднага щом пристигнат в папката ви Входящи. Файлът в Excel ще изглежда като следното изображение:

Предотвратете болезнената корупция на PST данни

Outlook спечели много благодарности поради различните си функции. Това обаче не означава, че е безпогрешно. Той все още може да бъде компрометиран по всяко време. Например, ако често затваряте вашия Outlook неправилно, е много вероятно вашите PST данни да бъдат изложени на опасност. В този случай, ако желаете ремонт PST данни, трябва да прибягвате до опитен инструмент, като напр DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително възстанови mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com