Как автоматично да приложите категориите на имейли към всички негови отговори и напред в Outlook

Когато отговаряте или препращате имейл, може да искате да приложите същите категории. В тази статия ще ви научим да осъзнавате това с VBA код.

Ако сте свикнали да присвоявате еднакви цветни категории на оригиналния имейл на всички негови отговори и пренасочвания, защо не оставите Outlook автоматично да постигне това? Въпреки че Outlook не предоставя такава директна функция, пак можете да я получите с помощта на VBA код. В следващите стъпки ще ви представим подробните стъпки и код.

Автоматично прилагайте категориите на имейли към всички негови отговори и напред

1. В самото начало стартирайте приложението Outlook.
2. След това натиснете клавишите “Alt + F11”, за да стартирате редактора на Outlook VBA.
3. След това копирайте следния код на VBA в проекта “ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. След това рестартирайте Outlook, за да активирате този проект.
5. Оттогава можете да го изпробвате, като следвате стъпките по-долу.

• Първо изберете имейл и натиснете бутона „Препращане“.
• След това ще се покаже имейл за препращане, в който можете да преминете към раздела „Опции“ и да натиснете иконата на разширението в долния десен ъгъл на групата „Още опции“.
• След това в изскачащия диалогов прозорец „Свойства“ можете да видите, че този имейл е назначен със същите цветови категории като оригиналния имейл.

Коригирайте повредения файл на Outlook

Предвид факта, че Outlook е уязвим, трябва да предприемете много действия, за да избегнете загубата на данни в Outlook. Например трябва да правите периодични архиви на данни. Освен това е необходимо да се пазите от неизвестни имейли, включително вградените връзки или прикачени файлове. Не на последно място, трябва да се снабдите с инструмент за външно коригиране с връх, като DataNumen Outlook Repair. Той е в състояние да ви помогне да извлечете максимални данни от корумпиран Outlook файл.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server фиксира и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com