3 метода за импортиране на имейли от папка на Windows във вашия Outlook

Може би сте запазили няколко имейла на Outlook в папката на Windows. Сега, ако искате да ги импортирате обратно в папка на Outlook, как можете да го направите? Тази статия ще ви научи на 3 начина.

Както всички знаем, Outlook предоставя вградена опция – „Запиши като“, чрез която можете да запазвате имейлите в папката на Windows. Въпреки това няма функция за повторно добавяне на експортираните имейли обратно в папката на Outlook. Следователно, ако искате да импортирате имейлите на Outlook обратно в Outlook, как можете да го реализирате? По-долу ще ви научим на 3 метода. Можете да изберете всеки според вашите предпочитания.

Метод 1: Плъзнете и пуснете за импортиране

1. В самото начало трябва да получите достъп до изходната папка на Windows, която съхранява имейлите на Outlook, които да бъдат импортирани в Outlook.
2. След това стартирайте вашето приложение Outlook.
3. След това отворете папката на Outlook, в която искате да импортирате имейлите.
4. Впоследствие трябва да стесните както прозореца на папката на Windows, така и прозореца на Outlook, докато междувременно можете да ги видите.
5. След това в папката на Windows можете да изберете един от имейлите на Outlook и след това да натиснете „Ctrl + A“, за да изберете всички.
6. По-късно можете да плъзнете и пуснете избраните имейли във видимата папка на Outlook, като следната екранна снимка:
7. Накрая ще видите, че всички имейли на Outlook са импортирани от папката на Windows в папката на Outlook, както е показано на изображението по-долу:

Метод 2: Използвайте „CreateItemFromTemplate“ във VBA

1. Към start с, в главния прозорец на Outlook, натиснете клавишните бутони „Alt + F11“.
2. След това ще получите достъп до прозореца на редактора на VBA на Outlook.
3. След това копирайте следния VBA код в празен модул.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. След това можете да натиснете бутона F5 в прозореца на текущия модул, за да start макроса.
5. След това трябва да прегледате изходната папка на Windows в изскачащия диалогов прозорец.
6. И накрая, след като изберете изходна папка, всички елементи на Outlook в тази папка ще бъдат импортирани в предварително дефинираната папка на Outlook.
7. Забележка: по този начин всички импортирани имейли са свежи нови имейли, които можете да композирате по желание, като следната екранна снимка:

Метод 3: Използвайте „OpenSharedItem“ във VBA

1. Подобно на метод 2, копирайте следните VBA кодове в друг модул.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. След това стартирайте този макрос, като натиснете клавишния бутон „F5“.
3. След това изберете папката източник.
4. В крайна сметка всички имейли ще бъдат импортирани като изображението по-долу:

Сравненията

Средства за блокиране на повреда на PST данни

Както всички знаем, Outlook идва предварително инсталиран с вграден инструмент – scanpst, Most време, той е способен да решава малки проблеми. Въпреки това, ако проблемите са изключително сериозни, вграденият инструмент ще се провали. Така че по-добре се върнете към по-мощен инструмент, като напр DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server корупция и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com