2 начина за отпечатване на списъците със задачи на Outlook с различни категории в различни страници

Ако сте присвоили различни цветови категории на вашите задачи в Outlook и сега искате да отпечатате списъците със задачи с различни категории на различни страници, можете да се обърнете към тази статия. Тук ще ви споделим 2 метода да го получите.

За да класифицирате и управлявате добре задачите си, може би сте приложили цветови категории към задачите си. Сега, ако искате да отпечатате списъците с вашите задачи с различни категории на различни страници, моля, прочетете нататък. По-долу ще ви представим 2 начина да го получите.

Метод 1: Ръчно отпечатване на списъци със задачи една по една

1. Първо, в Outlook отворете прозореца „Задачи“.
2. След това отворете папка със задачи.
3. След това натиснете „Ctrl + E“, за да активирате лентата „Търсене“.
4. След това в раздела „Търсене“ щракнете върху бутона „Категоризиране“.
5. От падащия списък изберете цветова категория.
6. Тогава в списъка ще останат само задачите с избраната категория.
7. Сега отидете на „Файл“ > „Печат“, за да отпечатате този списък със задачи.
8. След това по същия начин разпечатайте ръчно списъците със задачи с другите цветови категории една по една.

Метод 2: Пакетно отпечатване на списъците със задачи от VBA

1. В самото начало задействайте VBA редактор в съответствие с „Как да стартирате VBA код във вашия Outlook".
2. След това добавете препратката към „MS Excel Object Library ”според„Как да добавите Lib на обектrary Справка във VBA".
3. След това копирайте следния VBA код в модул.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. След това натиснете бутона „F5“, за да стартирате този макрос веднага.
5. Когато макросът приключи, списъците със задачи с различни категории ще бъдат отпечатани на различни страници, както е показано на следващата екранна снимка.

Върнете обратно ценни данни от компрометиран PST файл

Ако сте обект на недостъпен PST файл, следващата ви стъпка несъмнено е PST ремонт. В този случай можете първо да опитате инструмента за поправка на входящата кутия. При условие, че не успее, можете да продължите да опитвате друг външен инструмент, като напр DataNumen Outlook Repair. Той е в състояние да възстанови PST данни за бързо време.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително възстанови mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com