2種在回复郵件時刪除電子郵件原始背景色的方法

Outlook解決方案 2025 年 9 月 29 日

回复具有背景色的電子郵件時，如果要刪除它，可以使用本文介紹的以下2種方式。

一些用戶喜歡在電子郵件中使用其首選的背景顏色。因此，可以相信您可能曾經收到過包含自定義背景色的此類電子郵件。如果您不喜歡這種顏色，則在回復電子郵件時必須將其刪除。與往常一樣，要刪除顏色，您可以手動將“頁面顏色”更改為“無顏色”。但是，這很麻煩。實際上，您可以使用以下2條提示在回复時自動刪除背景色。

方法1：更改回複選項

默認情況下，答復設置為自動包含原始消息文本。在這種情況下，原始消息的背景色也必將包括在內。因此，如果您不想包含顏色，則可以更改回複選項。

首先，啟動您的Outlook。
然後轉到“文件”菜單。
接下來選擇“選項”。
隨後，在彈出的“ Outlook選項”對話框中切換到“郵件”選項卡。
之後，找到“答復和轉發”部分。
然後，從“回复郵件時”的下拉列表中選擇“不包括原始郵件”或“附加原始郵件”。
最後單擊“確定”以保存更改。現在您可以嘗試一下。

方法1的最大缺點之一是，回復中的郵件正文中將不包含原始電子郵件。因此，如果您不喜歡它，則可以選擇下一個方法。

方法2：使用Outlook VBA

首先，在Outlook中按“ Alt + F11”。
然後在VBA編輯器窗口中，打開一個未使用的模塊。
接下來，將以下VBA代碼複製並粘貼到其中。

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    Set objMail = objExplorer.Selection.Item(1)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim strReplyRecipient As String
    Dim objNewReply As Outlook.MailItem

    Set objReply = objMail.Reply
    strReplyRecipient = objMail.SenderEmailAddress
 
    Set objNewReply = Outlook.Application.CreateItem(olMailItem)
 
    With objNewReply
         .Recipients.Add (strReplyRecipient)
         .Recipients.ResolveAll
         .Subject = objReply.Subject
         .HTMLBody = objReply.HTMLBody
         .Display
    End With
 
    Cancel = True
End Sub

Private Sub objMail_ReplyAll(ByVal Forward As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyRecipients As Outlook.Recipients
    Dim objrecipient As Outlook.recipient
    Dim objNewReplyAll As Outlook.MailItem

    Set objReplyAll = objMail.ReplyAll
    Set objReplyRecipients = objReplyAll.Recipients
 
    Set objNewReplyAll = Outlook.Application.CreateItem(olMailItem)
    
    For Each objrecipient In objReplyRecipients
        objNewReplyAll.Recipients.Add (objrecipient.Address)
    Next
 
    With objNewReplyAll
         .Recipients.ResolveAll
         .Subject = objReplyAll.Subject
         .HTMLBody = objReplyAll.HTMLBody
         .Display
    End With
 
    Cancel = True
End Sub