VBA orqali jilddagi takroriy Outlook elementlarini qanday tezda olib tashlash mumkin

Agar siz Outlook-dagi takroriy elementlarni olib tashlamoqchi bo'lsangiz, ularni birma-bir qidirish va olib tashlash juda qiyin bo'ladi. Ushbu post sizga Outlook VBA yordamida buni qanday tezda bajarishni o'rgatadi.

Oldingi maqolamda - "Outlook-da takroriy elektron pochta xabarlarini qanday tezda topish va o'chirish mumkin”, siz takroriy xatlarni topish va oʻchirish hiylasini oʻrganishingiz mumkin, ular avval xatlarni mavzu boʻyicha, soʻngra qabul qilingan vaqt va qoʻshimchalar boʻyicha saralab, takroriy elementlarni topib, oxirgi marta takroriylarini tanlab, “Oʻchirish” tugmasini bosing. Garchi bu usul biroz qulayroq bo'lsa-da, lekin Outlook VBA-dan foydalanish bilan solishtirganda ancha muammoli. Quyidagi VBA kodlari orqali siz elektron pochta xabarlari, vazifalar, kontaktlar yoki uchrashuvlardan qat'i nazar, takroriy elementlarni bir marta bosish orqali tezda olib tashlashingiz mumkin. Endi kodlarni batafsil olish uchun o'qing.

Jilddagi takroriy Outlook elementlarini olib tashlang

1. Boshlash uchun Outlook dasturingizni ishga tushiring.
2. Keyin "Alt + F11" tugmachalarini bosing.
3. Keyingi VBA muharriri oynasida foydalanilayotgan modulni ochish uchun ikki marta bosing yoki "Qo'shish" > "Module" orqali yangi modulni to'g'ridan-to'g'ri kiriting.
4. Keyin modulga quyidagi VBA kodlarini nusxa ko'chiring va joylashtiring.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Shundan so'ng, ushbu makrosni raqamli imzolang va Outlook so'l xavfsizlik darajasini past darajaga o'zgartiring.
6. Keyinchalik, ushbu yangi VBA loyihasini ishga tushirishingiz mumkin. To'g'ridan-to'g'ri asboblar panelidagi "Ishga tushirish" belgisini bosing.
7. Keyinchalik, sizdan ikki nusxadagi elementlarni olib tashlamoqchi bo'lgan jildni tanlashingiz talab qilinadi.
8. Nihoyat, tanlangan jilddagi ikki nusxadagi elementlar bir vaqtning o'zida o'chiriladi.

Zaif PST ma'lumotlarini himoya qiling

PST fayli korruptsiyaga moyil bo'lganligi sababli, PST faylingizni himoya qilish uchun ko'p kuch sarflashingiz kerak. Masalan, Outlook noto'g'ri yopilishining oldini olishingiz kerak. Bunga qo'shimcha ravishda, siz mustahkamlikni tayyorlashingiz kerak Outlook tuzatish kabi vosita DataNumen Outlook Repair bu sizning PST-ni o'z vaqtida qutqara oladi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tiklash SQL Server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com