Outlook elektron pochtasining barcha rasm qo'shimchalarini faqat bitta sahifada qanday tezda chop etish mumkin

Printer siyohini va qog'ozini tejash uchun ba'zi foydalanuvchilar elektron pochtaga biriktirilgan barcha rasmlarni bitta sahifada bitta rasm o'rniga faqat bitta sahifada chop etishni xohlashadi. Endi ushbu maqola buni amalga oshirish uchun vositani baham ko'radi.

Hammamizga ma'lumki, tasvirlarni chop etish printer siyohini behuda sarflaydi. Shunday qilib, printer siyohini va qog'ozini tejash uchun rasmlarni alohida sahifalarda chop etish o'rniga bir xil sahifada ko'plab rasm qo'shimchalarini chop etishni afzal ko'rasiz. Outlook bunday xususiyatni taklif qilmasa ham, siz unga quyidagi vositalar yordamida erishishingiz mumkin.

Outlook elektron pochtasining barcha rasm qo'shimchalarini faqat bitta sahifada chop eting

1. Boshlash uchun Outlook ilovangizni ishga tushiring.
2. Keyin, Outlook oynasida "Alt + F11" tugmachalarini bosing.
3. Keyin, siz "Microsoft Visual Basic for Applications" oynasiga o'tasiz, unda avval "Microsoft Word Object Library" ni yoqishingiz kerak.
4. Shundan so'ng siz foydalanilmayotgan modulni ochishingiz kerak.
5. Keyinchalik, ushbu modulga quyidagi VBA kodini nusxa ko'chiring va joylashtiring.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Keyinchalik, siz elektron pochta ro'yxatiga qaytishingiz mumkin. Rasm qo'shimchalarini chop qilmoqchi bo'lgan elektron pochta manzilini tanlang yoki oching.
7. Keyin ushbu makroni ishga tushiring. Joriy so'l oynada "F5" tugmasini bosing yoki asboblar panelidagi "Ishga tushirish" belgisini bosing.
8. Nihoyat, so'l ishga tushirilganda, manba elektron pochtasining barcha rasm qo'shimchalari quyidagi skrinshot kabi bitta sahifada chop etiladi:

Buzilgan Outlook fayllari bilan shug'ullaning

Outlook-da ko'proq va ko'proq ma'lumotlar saqlanganligi sababli, Outlook faylingiz zaiflashmoqda. Bu turli xil ichki va tashqi omillar tufayli buzilgan bo'lishi mumkin. Bundan tashqari, Outlook korruptsiyasini oldindan aytish qiyin. Shunday qilib, siz Outlook korruptsiyalari bilan uchrashganda darhol va samarali qutqaruvni sug'urta qilishingiz mumkin. Masalan, siz ixtisoslashgan bo'lishingiz kerak PST ta'mirlash asbob, kabi DataNumen Outlook Repair yaqinida. U shabada kabi shikastlangan fayllarni skanerlaydi va tiklaydi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tiklash Sql Server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com