Word hujjatida bir jumlali paragraflarni qanday tezda topish mumkin

Ushbu postda biz sizga Word hujjatingizdagi barcha bitta jumlali paragraflarni VBA orqali topishning tezkor usulini ko'rsatmoqchimiz.

Vaqti-vaqti bilan, ba'zi hujjatlar formatlash va tuzilmalari uchun juda aniq talablarga ega bo'lishi mumkin. Masalan, sizda faqat bitta jumladan iborat paragraflarga ruxsat berilmasligi mumkin. Ushbu paragraflarni tanib olish qiyin emas, lekin bu vaqt talab etadi, ayniqsa bu uzoq hujjat.

Bugun biz sizga hujjatingizdagi barcha bir jumlali paragraflarni belgilashning tezkor usulini taklif qilamiz.

Bitta hujjatdagi barcha bir jumlali paragraflarni toping

1. Birinchidan, Word nuqtani jumla sifatida hisoblaydi. Shunday qilib, agar "janob" kabi so'zlar mavjud bo'lsa. yoki "Xonim", Word uni jumla sifatida ko'rib chiqadi. Bunday chalg'itishni istisno qilish uchun siz "janob" ni almashtirishingiz kerak. "janob" bilan. Va bitta jumlaning bandini topib bo'lgach, ularni orqaga o'zgartirishingiz mumkin. So'zlarni almashtirish uchun ushbu havolaga murojaat qilishingiz mumkin: Word hujjatingizdagi bir nechta elementlarni qanday topish va almashtirish
2. Ikkinchidan, VBA muharririni ishga tushirish uchun “Alt+ F11” tugmasini bosing.
3. Keyin "Oddiy" loyihani bosing.
4. Menyu panelidagi "Qo'shish" yorlig'ini bosing va ochiladigan menyuda "Modul" ni tanlang.
5. Keyin modulni ochish uchun uni ikki marta bosing.
6. Quyidagi kodlarni modulga joylashtiring:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Va nihoyat, "Ishga tushirish" tugmasini bosing yoki "F5" tugmasini bosing.

Ish tugaganligini bildiruvchi bunday xabar qutisini olasiz.

Bir nechta hujjatlardagi barcha bir jumlali paragraflarni toping

1. Boshlash uchun barcha maqsadli hujjatlarni papkaga joylashtirishingiz kerak.
2. Keyin quyidagi makroni o'rnating va ishga tushiring:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Ochilgan "Browse" oynasida hujjatlar saqlanadigan papkani tanlang va "OK" tugmasini bosing.

Keyin makro barcha bir jumlali paragraflarni ajratib ko'rsatadi va hujjatlarni ochiq qoldiradi. Agar hujjatda bir jumlali paragraf bo'lmasa, u yopiladi. Bundan tashqari, har bir hujjatdagi bir jumlali paragraflar sonini ko'rsatadigan xabarlar oynasi mavjud.

Ma'lumotlarni yo'qotish hodisasi bilan shug'ullanish

Foydalanuvchi xatolari va to'satdan elektr uzilishi Word dasturining o'limiga olib kelishi mumkin. Yiqilgan Word nafaqat kundalik ishiga ta'sir qilishi, balki olib kelishi mumkin dok zararBu hech qanday ma'lumotlar falokatining eng zerikarli qismi emas. Ma'lumotlarni darhol tiklash uchun ta'mirlash dasturini sotib olgan ma'qul.

Muallif kirish:

Vera Chen - ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc excelni tiklang va pdf dasturiy mahsulotlarni ta'mirlash. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com