Har bir rang turkumidagi Outlook uchrashuvlariga sarflangan umumiy vaqtni qanday tezda eksport qilish mumkin

Agar siz har bir rang toifasidagi uchrashuvlarga sarflagan umumiy vaqtingiz haqida hisobot yaratmoqchi bo'lsangiz, ushbu maqolada keltirilgan usuldan foydalanishingiz mumkin. Bu sizga qo'lda hisoblashni talab qilmasdan, buni tezda amalga oshirishga yordam beradi.

Ko'pgina foydalanuvchilar o'zlarining aksariyat faoliyatlarini Outlook taqvimida qayd etishga odatlangan. Bundan tashqari, ularni osonroq boshqarish va farqlash uchun ular har biriga toifalar ajratadilar. Bunday holda, ba'zi foydalanuvchilar har bir rang kategoriyasida taqvim elementlariga sarflangan umumiy vaqtni ko'rsatuvchi hisobot yaratishni xohlashadi. Shubhasiz, qo'lda sanash va kiritish qiyin. Shuning uchun, bu yerda biz bu vazifani oddiy bosish orqali qanday bajarish mumkinligini aytib beramiz.

Har bir rang turkumidagi uchrashuvlarga sarflangan umumiy vaqtni eksport qiling

1. Birinchidan, Outlook ilovasini ishga tushiring.
2. Keyin, Outlook oynasiga kirganingizdan so'ng, "Alt + F11" tugmachalarini bosishingiz mumkin.
3. Keyinchalik, siz "Ilovalar uchun Microsoft Visual Basic" oynasiga kirishingiz mumkin.
4. Keyin, sizdan “Microsoft Excel obyektlar kutubxonasi”ni yoqishingiz talab qilinadi. Bunga erishish uchun “Asboblar” > “Ma’lumotnoma” ni bosishingiz mumkin.
5. Keyin ishlatilmaydigan modulni topishingiz va ochishingiz kerak.
6. Shundan so'ng, ushbu modulga quyidagi VBA kodini nusxalashingiz kerak.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Nihoyat, asboblar panelidagi "Ishga tushirish" belgisini bosish yoki "F5" tugmachasini bosish orqali siz ushbu makrosni ishga tushirishingiz mumkin.
8. Keyin sizdan ma'lum bir kalendarni tanlashingiz talab qilinadi.
9. Siz tanlaganingizdan va "OK" tugmasini bosganingizdan so'ng, makros ishlashda davom etadi. Tugatgandan so'ng, fonda ko'rsatiladigan yangi Excel fayli paydo bo'ladi.
10. Unga kirishingiz mumkin. Bu quyidagi skrinshotga o'xshaydi:

Outlook atrofidagi potentsial tahdidlarga e'tibor bering

Outlook foydalanuvchilari barcha mumkin bo'lgan xavflarni, jumladan, noma'lum elektron pochta qo'shimchalari, o'rnatilgan havolalar va inson xatolaridan ehtiyot bo'lishlari kerak. Aks holda, Outlook istalgan vaqtda buzilishi mumkin. Bundan tashqari, muntazam ravishda Outlook ma'lumotlarining zaxira nusxalarini yaratish va maxsus ta'mirlash vositasini saqlash zaruriyati hisoblanadi. DataNumen Outlook Repair eng tavsiya etilgan tuzatish vositalaridan biridir. Bu mumkin Outlook-ni ta'mirlash bir zumda muammolar.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc shikastlangan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com