Qanday qilib Outlook papkasini barcha pastki papkalar va elementlar bilan Windows papkasiga tezda eksport qilish mumkin

Ba'zida siz Outlook papkasini barcha pastki papkalar va elementlar bilan Windows papkasiga ommaviy eksport qilishni xohlashingiz mumkin. Ushbu maqola sizga Outlook VBA-ni qo'llash usulini o'rgatadi.

Outlook jildini bir xil jild tuzilmasidagi barcha elementlar bilan mahalliy diskka eksport qilmoqchi bo'lsangiz, saqlash va qo'lda eksport qilishni tanlasangiz, bu sizga ko'p vaqt oladi. Shunday qilib, nega boshqa vositalarga, masalan, eksport vositalari yoki VBA kodlariga murojaat qilmaysiz? Bu erda biz sizga VBA kodining bunday qismini ochamiz. Bu sizga shabada kabi erishishga imkon beradi.

Outlook papkasidagi barcha pastki papkalar va elementlarni Windows papkasiga eksport qiling

1. Eng boshidanoq, Outlook dasturingizni ishga tushiring.
2. Keyin asosiy Outlook oynasida "Alt + F11" tugmachalarini bosing.
3. Keyinchalik, "Microsoft Visual Basic for Applications" oynasi ochiladi.
4. Keyin bo'sh modulni ochishingiz va unga quyidagi VBA kodlarini nusxalashingiz kerak.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Shundan so'ng, Outlook so'l sozlamalarida makroslarga ruxsat berishiga ishonch hosil qilishingiz kerak.
6. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchidan, yangi makro oynaga qayting.
• Keyin "ExportFolderWithAllItems" pastki dasturini bosing.
• Keyin ushbu makrosni ishga tushirish uchun F5 tugmachasini bosing.
• Shundan so'ng siz ma'lum bir jildni tanlashingiz kerak.
• Nihoyat, “Bajarildi” degan xabarni olganingizda, oldindan belgilangan mahalliy jildga kirishingiz mumkin. Barcha elementlar bir xil papka tuzilishida saqlanganligini topasiz.

Outlook halokatidan ma'lumotlarni yo'qotishning oldini oling

Ehtimol, siz Outlookning ko'plab ishdan chiqishiga duch kelgansiz. Ko'pincha, qayta ishga tushirilgandan so'ng, Outlook odatdagidek ishlay oladi. Biroq, bizning PST faylimiz buzilgan bo'lishi mumkin bo'lgan holat ham mavjud. O'sha paytda siz PST ma'lumotlaringizni tiklashga harakat qilasiz, masalan, tajribali vositaga murojaat qiling. DataNumen Outlook Repair. Qodir Outlook-ni tuzatish xatolarga yo'l qo'ying va buzilgan PST faylidan ma'lumotlarni to'ldirmasdan chiqarib oling.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc SQL Server ta'mirlash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com