Qanday qilib PST faylidagi barcha papkalarning o'lchami ma'lumotlarini Excel fayliga tezda eksport qilish mumkin

Agar siz PST faylidagi har bir jildning o'lchami haqida ma'lumotni tekshirmoqchi bo'lsangiz, ushbu maqolada ko'rsatilgan usuldan foydalanishingiz mumkin. U PST faylidagi barcha papkalarning o'lchami haqidagi ma'lumotlarni tezda Excel fayliga eksport qiladi.

PST faylingiz juda katta bo'lsa, har bir jildning hajmini tekshirishni xohlashingiz mumkin. Bu sizga qaysi biri kattaroq ekanligini osongina aniqlashga va hajmiga qarab mos arxivlashni amalga oshirishga yordam beradi. Umuman olganda, jild hajmini tekshirish uchun siz shunchaki papkani o'ng tugmasini bosib, "Xususiyatlar" ni tanlashingiz mumkin. Yangi qalqib chiquvchi dialog oynasida siz "Papka o'lchami" tugmasini bosishingiz mumkin. Biroq, agar siz ko'plab papkalarni yaratgan bo'lsangiz, o'lcham ma'lumotlarini birma-bir qo'lda tekshirish juda qiyin. Shunday qilib, agar siz PST faylidagi barcha papkalarning o'lchami haqida ma'lumot olishni istasangiz, quyidagi VBA kodidan foydalanishingiz mumkin. U barcha papka nomlari va hajmi haqidagi ma'lumotlarni bir martalik Excel fayliga eksport qiladi.

PST faylidagi barcha papkalarning o'lchami ma'lumotlarini Excel fayliga eksport qiling

1. S gatart bilan Outlook ilovangizni ishga tushiring.
2. Keyin "Tuzuvchi" yorlig'iga o'ting va VBA muharririga kirish uchun "Visual Basic" tugmasini bosing yoki "Alt + F11" tugmalarini bosing.
3. Keyingi "Ilovalar uchun Microsoft Visual Basic" oynasida ishlatilmaydigan modulni oching.
4. Keyinchalik, ushbu modulga quyidagi VBA kodlarini nusxa ko'chiring va joylashtiring.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Shundan so'ng, siz Outlook makro xavfsizlik darajasini past darajaga o'rnatishingiz kerak.
6. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Joriy makros oynasida F5 tugmachasini bosing.
• Keyin sizdan quyidagi rasm kabi PST faylini tanlashingiz so'raladi:
• Manba faylni tanlagandan so'ng, Outlook o'lcham ma'lumotlarini Excelga eksport qilishni boshlaydi.
• Makros tugagandan so'ng, siz quyidagi skrinshot kabi xabar olasiz.
• Va nihoyat, Excel faylini oldindan belgilangan mahalliy papkada topishingiz mumkin. Excel fayli quyidagicha ko'rinadi:

Tez-tez uchraydigan PST xatolar bilan shug'ullaning

Outlook xatolarga moyil bo'lganligi sababli, Outlook-da ko'p muammolarga duch kelgan bo'lishingiz mumkin. Xafagarchilik tug'diradigan PST muammolarini yaxshiroq va moslashuvchan tarzda engish uchun yaqin joyda tajribali va obro'li tuzatish yordam dasturini saqlash tavsiya etiladi, masalan DataNumen Outlook Repair. Qodir PST ni tuzatish shamol kabi muammolar.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc SQL Server qayta tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com