VBA orqali bir Outlook PST faylidan boshqasiga papka tuzilmasini qanday tezda nusxalash mumkin

Agar siz papka tuzilishini bitta Outlook PST faylidan boshqasiga ko'chirmoqchi bo'lsangiz, ushbu maqolada keltirilgan usuldan foydalanishingiz mumkin, bu sizga VBA-dan qanday foydalanishni o'rgatadi.

Ehtimol, elektron pochta xabarlaringizni yaxshiroq boshqarish uchun siz asosiy Outlook faylingizda bir nechta maxsus papkalarni yaratgansiz. Shunday qilib, yangi Outlook PST faylini yaratishda siz bir xil papka tuzilishini qo'llashingiz mumkin. Aslida, mening oldingi maqolamda - "Joriy jildni saqlash uchun 2 qadamrarYangi Outlook faylida chy”, siz an'anaviy usulni o'rganishingiz mumkin, unga erishish uchun "Arxiv" funksiyasidan foydalaniladi. Shunga qaramay, aslida bu hali ham biroz zerikarli. U bilan solishtirganda, uni olish uchun VBA kodlaridan foydalanish ancha tezroq bo'ladi. Shuning uchun, quyida biz sizga batafsil qadamlar va kodlarni aytib beramiz.

Papka tuzilishini bitta Outlook PST faylidan boshqasiga nusxalash

1. Eng boshida, start Outlook dasturingiz.
2. Keyin Outlook oynasida "Alt + F11" tugmachalarini bosing.
3. Keyin Outlook VBA muharriri oynasiga kirasiz.
4. Keyinchalik, quyidagi VBA kodlaridan nusxa ko'chiring va yangi modulga joylashtiring.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Shundan so'ng, makro xavfsizlik darajasini past darajaga o'zgartiring.
6. Keyinchalik VBA muharriri oynasiga qayting va makrosni ishga tushirish uchun “F5” tugmachasini bosing.
7. Nihoyat, so'l ishlagandan so'ng, siz "Bajarildi!" Degan xabarni olasiz.
8. Ushbu nuqtada siz pochta navigatsiya paneliga o'tishingiz mumkin. Siz quyidagi rasmdagi kabi PST manba fayli bilan bir xil papka tuzilishida joylashgan yangi Outlook maʼlumotlar faylini koʻrasiz:

Dispiritatsiya qiluvchi PST muammolarini enging

Outlook PST xatolikka moyil bo'lganligi sababli, ko'pchiligingiz Outlook-da turli muammolarga duch kelgan bo'lishingiz kerak. Ularga duch kelganingizda, avvalo, Outlook kirish qutisini ta'mirlash vositasidan foydalanishingiz mumkin. Agar u muvaffaqiyatsiz bo'lsa, siz kuchliroq uchinchi tomon vositasini qo'llashingiz mumkin, masalan DataNumen Outlook Repairmumkin Outlook-ni tuzatish PST xatolari shamol kabi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc SQL Server tuzatish va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com