Qanday qilib barcha qo'shimchalarni tezda siqish kerak Zip Outlook elektron pochtangizdagi fayl

Ba'zan siz elektron pochtadagi barcha qo'shimchalarni a ga siqib qo'yishingiz mumkin zip to'g'ridan-to'g'ri Outlook-da fayl. Bunday holda, ushbu xususiyatga erishish uchun ushbu maqolada keltirilgan VBA kodidan foydalanishingiz mumkin.

Odatiy bo'lib, Outlook o'zining biriktirma hajmi chegarasiga ega - POP20, IMAP yoki boshqa veb-ga asoslangan elektron pochta hisoblari uchun 3 MB va Exchange hisoblari uchun 10 MB. Shunday qilib, qo'shimchalarning umumiy hajmi chegaradan oshib ketganda, siz tegishli xatolarga duch kelasiz. Bunday holda, barcha qo'shimchalarni a ga siqish yaxshi variant zip file.

Biroq, ko'rib turganingizdek, Outlook bunday to'g'ridan-to'g'ri xususiyatni taklif qilmaydi. Ya'ni, birinchi navbatda, kerak zip ushbu fayllarni qattiq diskda saqlang va keyin yangi yaratilganni qayta biriktiring zip fayl. Aslida, ko'pchilik foydalanuvchilar buni Outlook ichida to'g'ridan-to'g'ri amalga oshirishga umid qilishadi. Ushbu talabga javoban, biz buni amalga oshirish uchun VBA dan qanday foydalanishni quyida ko'rib chiqamiz.

Barcha qo'shimchalarni a ga siqish Zip Fayl

1. Birinchidan, Outlook ilovasini ishga tushiring.
2. Keyin asosiy Outlook oynasida "Alt + F11" tugmachalarini bosing.
3. Keyin yangi Outlook VBA muharriri oynasida modulni oching.
4. Keyinchalik, modulga quyidagi VBA kodlarini nusxa ko'chiring va joylashtiring.

Sub ZipAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim objShell As Object
    Dim varTempFolder As Variant
    Dim varZipFile As Variant
 
    'Save the attachments to Temporary folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    varTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "dd-mm-yyyy- hh-mm-ss-")
    MkDir (varTempFolder)
    varTempFolder = varTempFolder & "\"
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        objAttachment.SaveAsFile (varTempFolder & objAttachment.FileName)
    Next
 
    'Create a new zip file
    varZipFile = InputBox("Specify a name for the new zip file", "Name Zip File", objMail.Subject)
    varZipFile = objFileSystem.GetSpecialFolder(2).Path & "\" & varZipFile & ".zip"
    Open varZipFile For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
 
    'Copy all the saved attachments to the new zip file
     Set objShell = CreateObject("Shell.Application")
     objShell.NameSpace(varZipFile).CopyHere objShell.NameSpace(varTempFolder).Items

     'Keep macro running until Compressing is done
     On Error Resume Next
     Do Until objShell.NameSpace(varZipFile).Items.Count = objShell.NameSpace(varTempFolder).Items.Count
        Application.Wait (Now + TimeValue("0:00:01"))
     Loop
     On Error GoTo 0
 
     'Delete all the attachments
     Set objAttachments = objMail.attachments
     While objAttachments.Count > 0
           objAttachments.Item(1).Delete
     Wend
 
     'Add the new zip file to the current email 
     objMail.attachments.Add varZipFile
 
    'Prompt
    MsgBox ("Complete!")
End Sub

5. Shundan so'ng, makroga ruxsat berilganligiga ishonch hosil qilish uchun Outlook makro sozlamalarini tekshirishingiz kerak.
6. Keyinchalik siz odatdagidek xabarlar oynasining Tez kirish asboblar paneliga yangi VBA loyihasini qo'shishingiz mumkin.
7. Oxir-oqibat, siz sinab ko'rishingiz mumkin.

• Birinchidan, yangi elektron pochta yarating va bir nechta fayllarni qo'shing. Yoki shunchaki ko'plab qo'shimchalari bo'lgan xatni oching.
• Keyin Tez kirish asboblar panelidagi makros tugmasini bosing.
• Keyinchalik siz uchun nom belgilashingiz kerak zip fayl va "OK" tugmasini bosing. Odatiy bo'lib, u pochta mavzusi bilan bir xil bo'ladi.
• Bir vaqtning o'zida barcha qo'shimchalar a ga siqiladi zip fayl, quyidagi skrinshot kabi:

Zipni oching .Zip Qo'shimchalar to'g'ridan-to'g'ri Outlook-da

Sizga "bilan" har qanday qo'shimchalar kelishi muqarrar..zip"fayl kengaytmasi vaqti-vaqti bilan. Ushbu stsenariyda siz bunday fayllarni mahalliy diskda saqlash va ochish o'rniga ularni Outlook ichidan to'g'ridan-to'g'ri ochishingiz mumkin. Outlookda bunday mahalliy xususiyat mavjud bo'lmasa ham, siz uni olish uchun VBA dan foydalanishingiz mumkin. Batafsil ma'lumot uchun boshqa maqolaga murojaat qilishingiz mumkin - "Qanday qilib arxivni ochish kerak .Zip VBA orqali Outlookda to'g'ridan-to'g'ri qo'shimchalar".

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sql tuzatish va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com