Outlook VBA bilan elektron pochta xabarlariga javob berish va yo'naltirish uchun turli xil shrift ranglarini avtomatik tarzda qanday ishlatish kerak

Odatiy bo'lib, Outlook-ga elektron pochta xabarlariga javob berish va ularni yo'naltirish uchun avtomatik ravishda turli xil shrift ranglaridan foydalanishga ruxsat bera olmaysiz. Shuning uchun, agar sizda shunday talab bo'lsa, aqlli yondashuvni o'rganish uchun ushbu postni o'qishingiz mumkin.

Outlook faqat elektron pochta xabarlariga javob berish va yuborish uchun ishlatiladigan shriftni belgilashga ruxsat beradi. Siz "Fayl" > "Tanlovlar" bo'limiga o'tishingiz mumkin. So'ngra, "Outlook Options" da "Pochta" yorlig'iga o'ting va "Kantreliya va shriftlar ..." tugmasini bosing. Keyingi oynada siz "Xabarlarga javob berish yoki yo'naltirish" da "Shrift" tugmasini ko'rishingiz mumkin. Unga bosing va keyin siz elektron pochta xabarlariga javob berish va yuborish uchun ma'lum bir shrift rangini o'rnatishingiz mumkin.

Biroq, ko'p foydalanuvchilar elektron pochta xabarlariga javob berish yoki yo'naltirish uchun turli xil shrift ranglarini ishlatishga umid qilishadi. Outlook buning uchun to'g'ridan-to'g'ri xususiyatlarni taqdim etmasa ham, uni VBA kodi bilan amalga oshirish mumkin. Endi VBA kodining bunday qismini olish uchun o'qing.

Elektron pochta xabarlariga javob berish va boshqa shrift ranglarini avtomatik ishlatish

1. Boshlash uchun Outlook dasturini ishga tushiring.
2. Keyin VBA muharririni ishga tushiring.Outlook-da VBA kodini qanday ishlatish kerak".
3. Keyingi, "ga muvofiqVBA da obyekt kutubxonasi havolasini qanday qo'shish mumkin", "MS Word obyektlar kutubxonasi" ga havola qo'shing.
4. Keyinchalik, quyidagi kodni "ThisOutlookSession" loyihasiga nusxalang.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Shundan so'ng, ushbu so'lni faollashtirish uchun Outlook-ni qayta ishga tushiring.
6. Nihoyat, siz sinab ko'rishingiz mumkin.

• Emailni tanlang yoki oching.
• Keyin "Javob berish" tugmasini bosing. Elektron pochtaga javob berishda siz ba'zi so'zlarni tanada yozishingiz mumkin. Shrift rangi pushti bo'lishi kerak.
• Yoki "Hammasiga javob berish" tugmasini bosing. Yangi "hammasiga javob berish" pochtasida so'zlarni tanaga kiriting. Shrift rangi, albatta, yashil.
• Xuddi shunday, "O'tkazish" tugmasini bosing. Yo'naltiruvchi pochtada yangi so'zlar ko'k rangda ko'rsatiladi.

Ishonchli dasturiy ta'minotga murojaat qiling

Taqdirda Outlookning buzilishi, aksariyat foydalanuvchilar Outlook tiklash dasturiga murojaat qilishadi. Bozorda bunday dasturlar juda ko'p. Va ularning ba'zilari hatto bepul. Shunga qaramay, siz noma'lum manbalardan olingan dasturlardan ehtiyot bo'lishingiz kerak, chunki ular hozirgi holatni yanada yomonlashtirishi mumkin. Siz ishonchli va tajribali vositadan foydalanishingiz kerak, masalan DataNumen Outlook Repair.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc buzilgan sql va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com