Muayyan elektron pochtaga kutilgan vaqt ichida javob ololmasa, qanday qilib bildirishnoma olish mumkin

Ushbu maqola sizga ma'lum bir vaqt ichida ma'lum bir elektron pochtaga javob olmaganingizda, Outlook sizga avtomatik ravishda bildirishnoma yuborishni so'rashiga imkon berish uchun VBA-dan foydalanishni o'rgatadi.

Ba'zan, hayotiy muhim elektron pochta xabarlari uchun siz uning javoblarini albatta kutasiz. Boshqacha qilib aytganda, oluvchi sizga imkon qadar tezroq javob berishiga umid qilishingiz kerak. Aks holda, kutilgan vaqt ichida javobni hali olmagan bo'lsangiz, qabul qiluvchiga yana bir bor bildirishnoma yuborasiz. Shuning uchun, ushbu talabga javoban, bu erda biz VBA-dan foydalanadigan, Outlook-ni bunday holatda sizni avtomatik ravishda ogohlantirish va so'rash uchun ishlatadigan usulni taqdim etamiz. Murakkab qadamlar va kodlarni olish uchun o'qing.

Muayyan elektron pochtaga kutilgan vaqt ichida javob ololmasa, bildirishnoma oling

1. Eng boshida, start Outlook.
2. Keyin ma'lum elektron pochtaga ma'lum bir eslatma vaqtini belgilashingiz kerak.

• Birinchidan, maxsus elektron pochtani o'ng tugmasini bosing.
• Keyin "Kuzatuv" > "Eslatma qo'shish" ni tanlang.
• Muloqot oynasida siz eslatma vaqtini uning javobini olmoqchi bo'lgan vaqt bilan bir xil belgilashingiz mumkin.

3. Shundan so'ng, Outlook VBA muharririga kirish uchun "Alt + F11" tugmachalarini bosing.
4. Keyin yangi oynada "ThisOutlookSession" loyihasini oching va unga quyidagi kodlarni nusxalang.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Keyinchalik, ushbu kodni imzolang.
6. Raqamli imzolangan makroslarga ruxsat berish uchun Outlook makro sozlamasini keyinroq o'zgartiring.
7. Oxir-oqibat restart Outlook yangi makroni faollashtirish uchun. Bundan buyon Outlook quyidagi tarzda ishlaydi:

• Agar siz eslatma paydo bo'lishidan oldin ma'lum bir elektron pochtaga javob olgan bo'lsangiz, Outlook avtomatik ravishda bayroqni o'chiradi va eslatmani o'chiradi.
• Agar eslatma ishga tushganda javob olmagan bo'lsangiz, Outlook sizdan keyingi bildirishnomani elektron pochta orqali yuborishingizni so'raydi. Agar siz "Ha" ni tanlasangiz, elektron pochta xabari yuboriladi. Agar "Yo'q" ni tanlasangiz, so'rov darhol yo'qoladi.

Zerikarli Outlook muammolarini hal qiling

Outlook xatoga moyil bo'lgani uchun, oldini olish uchun Outlookning buzilishi, siz faqat inbox vositasi, Scanpst.exe ga tayanmasligingiz kerak edi. Siz boshqa kuchli va obro'li ta'mirlash vositasini tayyorlashingiz kerak, masalan DataNumen Outlook Repair, bu Scanpst.exe hal qila olmaydigan zerikarli muammolarni hal qilishi mumkin.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sql buzilishi va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com