Outlook kontakt guruhining barcha a'zolarini Excelga eksport qilishning 2 usuli

Ba'zan siz Outlook kontakt guruhidagi a'zolarni eksport qilishni xohlashingiz mumkin. Shunday qilib, ushbu maqola sizga guruh a'zolarini Excelga chiqarishning 2 usulini aytib beradi.

Outlook ma'lum bir kontakt papkasining barcha kontaktlarini eksport qilish imkonini beruvchi mahalliy xususiyatni taklif etadi. Biroq, bu sizga kontakt guruhlarini eksport qilishga ruxsat bermaydi, kontakt guruhlaridagi a'zolarni ajratib olish haqida gapirmasa ham bo'ladi. Shuning uchun, agar siz tanlangan kontakt guruhi a'zolarini ajratib olishni istasangiz, biroz ko'proq harakat qilishingiz kerak. Bu erda siz murojaat qilishingiz mumkin bo'lgan ikkita maslahat.

1-usul: Boshqacha saqlash orqali guruh a'zolarini ajratib oling

1. Eng boshida Outlookni ishga tushiring.
2. Keyin a'zolarini ajratib olishingiz kerak bo'lgan kontakt guruhini toping va tanlang.
3. Keyin "Fayl" menyusiga o'ting va "Boshqa saqlash" tugmasini bosing.
4. Keyinchalik, ochilgan "Boshqa saqlash" dialog oynasida saqlash uchun maqsad papkani tanlang va "Tiri sifatida saqlash" ochiladigan ro'yxatidan "Faqat matn" ni tanlang.
5. Va keyin "Saqlash" tugmasini bosing.
6. Shundan so'ng, Excel-ni oching va yangi Excel faylini yarating.
7. Keyinchalik siz "Fayl" ga o'tishingiz va "Ochish" tugmasini bosishingiz kerak.
8. Keyingi "Ochish" dialog oynasida siz avval kontaktlar guruhini hozir saqlagan papkaga kirishingiz kerak.
9. Keyin "Fayl nomi" qatoridagi ikkinchi katakchani bosing va ochiladigan ro'yxatdan "Barcha fayllar" ni tanlang.
10. Shundan so'ng, kontaktlar guruhi uchun Matn fayliga o'ting va "Ochish" tugmasini bosing.
11. Qalqib chiquvchi "Matnni import qilish ustasi" dialog oynasida "Ajratilgan" tanlanganligiga ishonch hosil qiling va "Finish" tugmasini bosing.
12. Nihoyat, siz quyidagi skrinshot kabi a'zolarni olasiz:

2-usul: Guruh a'zolarini Outlook VBA orqali chiqarib oling

1. Birinchidan, Outlook-da "Alt + F11" tugmachalarini bosing.
2. Keyin VBA muharriri oynasida yangi modulni oching.
3. Keyinchalik, unga quyidagi VBA kodlarini nusxalang.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

4. Shundan so'ng siz odatdagidek tez kirish asboblar paneliga (QAT) makrosni qo'shishingiz mumkin.
5. Keyinchalik, siz kontakt guruhini tanlashingiz va QAT-dagi so'l tugmasini bosishingiz mumkin.
6. Eksportdan so'ng siz "Eksport tugallandi!" xabarini olasiz.
7. Oxir-oqibat, Excel faylini VBA kodlarida oldindan belgilangan papkada topishingiz mumkin. Uni oching, siz quyidagi rasmdagi kabi guruh a'zolarini ko'rishingiz mumkin:

Oldingi PST ma'lumotlaringizni qaytarib oling

Outlook ishdan chiqishga moyil bo'lganligi sababli, sizning PST ma'lumotlaringiz hech qanday alomatsiz buzilishi mumkin. Shuning uchun siz PST fayllaringizning muntazam zaxira nusxasini yaratishingiz kerak. Bundan tashqari, siz kuchli vositani tayyorlashingiz kerak edi, masalan DataNumen Outlook Repairmumkin Outlook-ni ta'mirlash ma'lumotlarni o'z vaqtida olish.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sql-ni tuzatish va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com