Outlook-dagi barcha o'qilgan kvitansiyalarni qanday qilib ommaviy ravishda o'chirish mumkin

Qabul qiluvchilar elektron pochtangizni o'qiganligini tasdiqlash uchun elektron pochta xabarini yozishda o'qish kvitansiyasini so'rashingiz mumkin. Bunday holatda, pochta qutingiz bunday o'qish kvitansiyalari bilan to'ldirilgan bo'lishi mumkin. Endi, ushbu post sizga ularni qanday qilib butunlay o'chirishni o'rgatadi.

Maqolani o'qib chiqqandan so'ng "Outlook-dagi barcha etkazib berish kvitansiyalarini qanday qilib ommaviy ravishda o'chirish mumkin", siz barcha o'qilgan kvitansiyalarni ommaviy yo'q qilish yondashuvi haqida o'ylashingiz mumkin. Aslida, ikki xil kvitansiya o'rtasidagi aniq farq ularning sub'ektlaridadir. Yetkazib berish kvitansiyasida mavzu bo‘yicha “Yetkazib berildi”, lekin o‘qilgan kvitansiyasida “O‘qilgan” yozuvi mavjud. Shuning uchun, siz barcha o'qilgan kvitansiyalarni to'plamda o'chirish uchun xuddi shu usuldan foydalanishingiz mumkin. Quyida biz sizga aniq qadamlarni batafsil o'rgatamiz.

To'plamli barcha o'qilgan kvitansiyalarni o'chirish

1. Boshida, Outlook-ni ishga tushiring.
2. Keyin, “Alt + F11” orqali “Outlook VBA muharriri”ga o‘ting.Outlook-da VBA kodini qanday ishlatish kerak".
3. Keyin, yangi oynada bo'sh modulni oching va unga quyidagi kodni qo'ying.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Shundan so'ng, birinchi pastki dasturga bosing.
5. Nihoyat, "F5" tugmachasini bosing.
6. Bir vaqtning o'zida makro Outlook-dan barcha o'qilgan kvitansiyalarni o'chirish uchun ishlaydi.
7. U tugagach, siz quyidagi skrinshot kabi natija haqida xabar olasiz.
8. Hozirda siz pochta papkalarini tekshirishingiz mumkin. Barcha o'qilgan kvitantsiyalar yo'qoldi.

Outlook ma'lumotlarini himoya qilish

Outlook fayli korruptsiyaga moyil bo'lsa-da, biz uni himoya qilish uchun choralar ko'rishimiz mumkin. Masalan, biz Outlook faylini kichik hajmda saqlashimiz, uni zararli omillardan himoya qilishimiz va muntazam ravishda zaxira nusxasini yaratishimiz kerak. Va nihoyat, eng muhimi, siz kuchli tashqi PST ta'mirlash vositasini tayyorlaganingiz ma'qul DataNumen Outlook Repair. Bu ta'mirlashga katta ta'sir ko'rsatadi buzilgan Outlook file.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sql ta'mirlash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com