Turli xil rang toifalaridagi Outlook uchrashuvlari uchun turli eslatma vaqtlarini avtomatik sozlash

Agar siz Outlook uchrashuvlarini rang toifalari bo'yicha tasniflayotgan bo'lsangiz va turli rang toifalaridagi uchrashuvlar uchun turli eslatma vaqtini belgilashni istasangiz, ushbu maqolaga murojaat qilishingiz mumkin. Bu erda biz sizga Outlook VBA yordamida buni amalga oshirishni o'rgatamiz.

Masalan, siz uchrashuvlarni ikki guruhga ajratyapsiz. Biri "Tashqi" rang kategoriyasida, chunki uchrashuv joyi juda uzoqda, ikkinchisi esa joy aynan shu yerda joylashganligi sababli "Joyida" rang kategoriyasida. Endi siz Outlook "tashqi" uchrashuvning eslatma vaqtini boshlanishidan 1 soat oldin va "joyida" uchrashuv boshlanishidan 15 daqiqa oldin avtomatik ravishda o'rnatishini xohlaysiz. Ushbu talabni hisobga olgan holda, bundan keyin biz tezkor usulni baham ko'ramiz.

Turli xil rangdagi toifadagi uchrashuvlar uchun avtomatik ravishda turli eslatmalarni o'rnatish

1. Boshlash uchun Outlook ilovangizni ishga tushiring.
2. Keyin VBA muharriri oynasiga kirish uchun “Alt + F11” tugmachalarini bosing.
3. Keyinchalik, keyingi oynada quyidagi VBA kodini nusxa ko'chiring va "ThisOutlookSession" loyihasiga joylashtiring.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Keyinchalik, ushbu makrosni ishga tushirish uchun "Application_Startup" kichik dasturiga o'tishingiz va "F5" tugmasini bosishingiz kerak.
5. O'shandan beri har safar standart taqvimga yangi uchrashuv qo'shilganda yoki siz mavjud uchrashuvni o'zgartirsangiz, Outlook avtomatik ravishda uchrashuv toifalarini tekshiradi va boshqa eslatma vaqtini avtomatik ravishda o'rnatadi.

Outlook xatolarini yo'q qilish

Outlook bilan vaqti-vaqti bilan turli muammolar yuzaga kelishi mumkin. Shuning uchun foydalanuvchilar uchun Outlook muammolarini qanday hal qilishni o'rganish juda muhimdir. Boshlash uchun, muntazam ravishda Outlook ma'lumotlarining zaxira nusxalarini yaratganingiz ma'qul. Bundan tashqari, agar imkoningiz bo'lsa, kuchli saqlash tavsiya etiladi Outlook-ni ta'mirlash kabi yaqin atrofdagi asbob DataNumen Outlook Repair. U Outlook bilan bog'liq muammolarni aniqlash va keyin ularni osonlik bilan hal qilish uchun PST faylingizni skanerlashi mumkin.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc sqlni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com