Outlook-da javob bermagan muhim elektron pochta xabarlarini qanday avtomatik tarzda ajratib ko'rsatish mumkin

Muhim xatlarga javob berishni eslab qolish uchun Outlookdan siz javob bermagan muhim elektron pochta xabarlarini ularni ajratib ko'rsatish uchun ma'lum bir manifest rangda ko'rsatishini xohlashingiz mumkin. Endi ushbu maqola sizga uni qanday qilib olishni o'rgatadi.

Hech qachon muhim elektron pochta xabarlarini o'tkazib yuborgan va ularga o'z vaqtida javob bermaganmisiz? Agar siz bunday muammolarga duch kelgan bo'lsangiz, ehtimol Outlook sizga javob bermagan muhim elektron pochta xabarlarini ajratib ko'rsatishiga umid qilasiz. Endi, quyida, biz sizga VBA bilan erishish uchun yo'l-yo'riq beramiz. Agar siz VBA bilan tanish bo'lmasangiz, iltimos, mening oldingi maqolamga qarang - "Outlook-da VBA kodini qanday ishlatish kerak” shu bilan birga.

Siz javob bermagan muhim elektron pochta xabarlarini avtomatik ajratib ko'rsatish

1. Eng boshida Outlook-da "Alt + F11" orqali VBA muharririga kiring.
2. Keyin, yangi oynada quyidagi kodni "ThisOutlookSession" loyihasiga nusxalang.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Shundan so'ng, kursorni "Application_Startup" makrosiga olib boring va "F5" tugmasini bosing.
4. Keyinchalik, bu oynani yoping.
5. Keyinchalik, Inbox-dagi elementlar uchun shartli formatlash qoidasini yaratish uchun quyidagi amallarni bajaring.

• Avval "Kirish qutisi" jildiga o'ting.
• Keyin "Ko'rish" yorlig'iga o'ting va "Ko'rish sozlamalari" ni bosing.
• Yangi dialog oynasida "Shartli formatlash" tugmasini bosing.
• Keyingi "Shartli formatlash" dialog oynasida "Qo'shish" tugmasini bosing va yangi qoida nomini kiriting, masalan, "Javob berilmagan muhim elektron pochta xabarlari".
• Keyinchalik, "Shrift ..." tugmasini bosing va ochilgan "Shrift" dialog oynasida shrift uslubi va rangini o'rnating.
• Shriftni belgilagandan so'ng, "Shartli formatlash" dialog oynasida "Shart ..." tugmasini bosing.
• Keyinchalik, "Filtr" ekranida, "Kengaytirilgan" yorlig'ida ikkita filtr qo'shing.

1. “Ahamiyat” > “teng” > “Yuqori”
2. “Javob berildi” > “(aniq)” > “Yo‘q”

• Nihoyat, ushbu formatlash qoidasini saqlash uchun bir qator "OK" tugmasini bosing.

6. Kirish qutisiga qaytganingizdan so'ng, siz javob bermagan barcha muhim xatlar ma'lum shrift va rangda ta'kidlangan.

Outlook ma'lumotlarini himoya qilishda sust bo'lmang

Ko'p sonli foydalanuvchilarda hali ham ma'lumotlarning buzilishi hech qachon xayollariga kelmaydi, degan fikr bor. Aslida, bunday fikrlar mutlaqo noto'g'ri va xavflidir. Ko'pincha, kichik xato ma'lumotlarning osongina yo'qolishiga olib kelishi mumkin. Masalan, agar siz tasodifan noma'lum elektron pochta xabarlaridagi zararli havolani bossangiz, Outlook faylingiz virus bilan yuqtirilgan bo'lishi va hatto shikastlanishi mumkin. Shuning uchun, ma'lumotlarni himoya qilishda doimo ehtiyot bo'lishingiz kerak, masalan, muntazam PST zaxira nusxasini saqlash va kuchli tuzatish vositasini tayyorlash, masalan. DataNumen Outlook Repairmumkin Outlook-ni tuzatish muammolar bir zumda.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc mdf-ni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com