Noma'lum jo'natuvchilardan kiruvchi Outlook elektron pochta xabarlarida giperhavolalarni qanday avtomatik o'chirish mumkin

Zararli havolalarni bloklash uchun Outlook-ni noma'lum jo'natuvchilardan kiruvchi xatlardagi giperhavolalarni avtomatik o'chirib qo'yadigan qilib sozlaganingiz ma'qul. Ushbu maqola VBA kodlarining bir qismini ochib beradi, bu sizga uni mantar kabi olishingizga yordam beradi.

Ko'pgina foydalanuvchilar elektron pochta orqali yuboriladigan viruslar ularning Outlook fayliga hujum qilganidan shikoyat qiladilar. Ko'pincha, ular noma'lum jo'natuvchilardan kelgan elektron pochta xabarlariga osongina ishonishadi. Shunday qilib, ular xatlardagi giperhavolalarni yuklab oladilar yoki bosadilar. Endi, keyin biz bir usulni baham ko'ramiz. U Outlook-ga noma'lum jo'natuvchilardan kiruvchi xatlarning giperhavolalarini avtomatik ravishda o'chirishga ruxsat berishi mumkin. Agar sizda bunday ehtiyojlar bo'lsa, batafsilroq ma'lumot olish uchun o'qing.

Noma'lum jo'natuvchilardan kiruvchi xatlardagi giperhavolalarni avtomatik ravishda o'chirib qo'yish

1. Sifatida uchuntart, Outlook-da "Alt + F11" tugmalari yordamida VBA muharririga o'ting.
2. Keyin, yangi ekranda bet ga muvofiq "MS VBScript Regular Expressions" ob'ektini qo'shingost "Ob'ektni qanday qo'shish kerakrary VBA-da havola".
3. Keyin, quyidagi kodni nusxa ko'chiring va "ThisOutlookSession" loyihasiga joylashtiring.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Shundan so'ng, ushbu makrosni res orqali faollashtiringtart Outlook yoki “Application_Startup” kichik dasturi.
5. O'shandan beri har safar jo'natuvchidan kelgan va standart Kontakt jildida saqlanmagan elektron pochta xabari Inboxga tushganda, Outlook undagi giperhavolalarni avtomatik ravishda o'chirib qo'yadi.

Outlook himoyasida bir nechta zarurat masalalari

Outlook shikastlanishga moyil bo'lganligi sababli, Outlook faylini himoya qilish juda qiyin. Bu erda Outlook ma'lumotlarini himoya qilish paytida bo'lishi kerak bo'lgan bir nechta narsalarni sanab o'tamiz. Avvalo, siz muntazam ravishda Outlook ma'lumotlarini zaxiralashingiz kerak. Bundan tashqari, zararli qo'shimchalar yoki giperhavolalar kabi barcha mumkin bo'lgan xavflardan ehtiyot bo'lishingiz kerak. Va nihoyat, siz kuchli Outlook tuzatish vositasini oldindan tayyorlashingiz kerak, masalan DataNumen Outlook Repair. Bu, albatta, kerak bo'lganda foydali bo'ladi PST-ni ta'mirlash fayl, lekin kirish qutisini tuzatish vositasi muvaffaqiyatsizlikni isbotlaydi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc shikastlangan mdf va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com