Word jadvalidagi bo'sh qatorlar va ustunlarni o'chirishning 3 ta tezkor usuli

Ushbu postda biz sizga Word jadvalingizdagi bo'sh qatorlar va ustunlarni o'chirishning 3 ta tezkor usulini tushuntirib beramiz.

Jadvallar hujjat uchun, ayniqsa har xil turdagi ma'lumotlarni saqlash uchun zarurdir. Ba'zan uzun jadval bir sahifadan oshib ketishi va bir nechta sahifaga cho'zilishi mumkin. Shunday qilib, jadval uzun va murakkablashsa, uni soddalashtirish uchun choralar ko'rishingiz mumkin. Masalan, keraksiz bo'sh satr va ustunlarni o'chirishingiz mumkin.

Quyida siz foydalanishingiz mumkin bo'lgan 3 ta usul mavjud.

1-usul: bo'sh qatorlar va ustunlarni qo'lda o'chirish

1. Birinchidan, bo'sh satr yoki ustunni tanlang.
2. Keyin kontekst menyusini olish uchun o'ng tugmasini bosing. Menyuda mos ravishda "Qatorlarni o'chirish" yoki "Ustunlarni o'chirish" ni tanlang.

Afsuski, siz bir nechta ketma-ket bo'lmagan satr yoki ustunlarni tanlay olmaysiz va ularni shu tarzda birga o'chira olmaysiz. Ushbu talab uchun oldingi maqolamizga murojaat qilishingiz mumkin: Word jadvalidagi bir nechta satr yoki ustunlarni to'plamda yo'q qilishning 5 ta tezkor usuli

2-usul: Jadvaldagi barcha bo'sh qatorlar va ustunlarni to'plam bilan o'chirish

1-usul o'z cheklovlariga ega. Shunday qilib, biz sizga VBA kodlari orqali jadvaldagi satrlar va ustunlarni ommaviy olib tashlash usulini taklif qilamiz.

1. Boshlash uchun kursorni maqsadli jadval ichiga joylashtiring.
2. Ikkinchidan, “Alt+ F11” tugmachalarini bosib VBA muharririni ishga tushiring.
3. Tahrirlovchida avval "Oddiy" loyihani bosing.
4. Keyin menyu panelidagi "Qo'shish" yorlig'ini bosing.
5. Ochilgan menyuda "Modul" ni tanlang.
6. Modulni ochish uchun uni ikki marta bosing va u erga quyidagi kodlarni joylashtiring:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Nihoyat, menyu panelidagi "Ishga tushirish" tugmasini bosing yoki "F5" tugmasini bosing.

Bir necha soniya ichida siz ushbu jadvaldagi barcha bo'sh qatorlar va ustunlarni o'chirib tashlaysiz.

3-usul: Hujjatdagi barcha jadvallardagi barcha bo'sh qatorlar va ustunlarni to'plam bilan o'chirish

1. Birinchidan, so'lni o'rnatish va ishga tushirish uchun 2-usuldagi amallarni takrorlang.
2. Faqat bu safar makroni quyidagi bilan almashtiring:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Buzilgan hujjatni tiklash

Hozirgi kunda yo'qolgan ma'lumotlarni qayta tiklashning bir nechta usullari mavjud. Masalan, zaxira nusxalariga murojaat qilish har doim sizning ustuvor vazifangiz bo'lib qoladi. Agar bu sizning eng so'nggi ma'lumotlarni qaytarib olish ehtiyojingizni qondirmasa, unda siz ... ni sinab ko'rishingiz mumkin. doc ta'mirlash vositasi.

Muallif kirish:

Vera Chen - ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc xlsx ta'mirlash va pdf dasturiy mahsulotlarni ta'mirlash. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com