Turli sahifalarda turli toifalarga ega Outlook vazifalari ro'yxatini chop etishning 2 usuli

Agar siz Outlook vazifalaringizga turli rang toifalarini tayinlagan bo'lsangiz va endi turli sahifalarda turli toifadagi vazifalar ro'yxatini chop qilmoqchi bo'lsangiz, ushbu maqolaga murojaat qilishingiz mumkin. Bu erda biz sizga uni olishning 2 usulini baham ko'ramiz.

Vazifalaringizni tasniflash va yaxshi boshqarish uchun, ehtimol siz o'z vazifalaringizga rang toifalarini qo'llagansiz. Endi, agar siz o'zingizning vazifalaringiz ro'yxatini turli sahifalarda turli toifalar bilan chop qilmoqchi bo'lsangiz, o'qing. Quyida biz sizga uni olishning 2 ta usulini taqdim etamiz.

1-usul: Vazifalar ro'yxatini birma-bir qo'lda chop etish

1. Birinchidan, Outlook-da "Vazifalar" paneliga kiring.
2. Keyin, Vazifa papkasini oching.
3. Keyin, "Qidiruv" tasmasini faollashtirish uchun "Ctrl + E" tugmalarini bosing.
4. Shundan so'ng, "Qidiruv" yorlig'ida "Kategoriyalash" tugmasini bosing.
5. Ochiladigan ro'yxatdan rang toifasini tanlang.
6. Keyin ro'yxatda faqat tanlangan toifadagi vazifalar qoladi.
7. Endi ushbu vazifalar ro'yxatini chop etish uchun "Fayl" > "Chop etish" ga o'ting.
8. Keyinchalik, xuddi shu tarzda, boshqa rang toifalari bilan vazifalar ro'yxatini birma-bir qo'lda chop eting.

2-usul: VBA tomonidan topshiriqlar ro'yxatini ommaviy chop etish

1. Eng boshida “VBA muharririni ishga tushiring.Outlook-da VBA kodini qanday ishlatish kerak".
2. Keyin, "MS Excel obyektlar kutubxonasi" ga "ga muvofiq" havolasini qo'shing.VBA da obyekt kutubxonasi havolasini qanday qo'shish mumkin".
3. Keyin, quyidagi VBA kodini modulga nusxalang.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Shundan so'ng, ushbu makrosni darhol ishga tushirish uchun "F5" tugmachasini bosing.
5. Makros tugagach, quyidagi skrinshotda ko'rsatilganidek, turli toifadagi vazifalar ro'yxati turli sahifalarda chop etiladi.

Buzilgan PST faylidan qimmatli ma'lumotlarni qaytarib oling

Agar siz PST fayliga kirish imkoniga ega bo'lsangiz, keyingi qadamingiz shubhasiz PST ta'mirlash. Bunday holda, siz birinchi navbatda kirish qutisini tuzatish vositasini sinab ko'rishingiz mumkin. Agar u muvaffaqiyatsiz bo'lsa, siz boshqa tashqi vositani sinab ko'rishni davom ettirishingiz mumkin, masalan DataNumen Outlook Repair. U tezda PST ma'lumotlarini tiklashga qodir.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc mdf-ni tiklash va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com