Barcha bayroqli Outlook elektron pochta xabarlari ro'yxatini Excelga eksport qilishning 2 ta tezkor usuli

Agar siz Outlook pochta qutingizdan Excelga barcha belgilangan elektron pochta xabarlari roʻyxatini eksport qilmoqchi boʻlsangiz, ushbu maqolada keltirilgan ikkita usuldan birini qoʻllashingiz mumkin.

Masalan, barcha belgilangan elektron pochta xabarlari bilan tezroq ishlash yoki ularni boshqa birov bilan baham ko'rish uchun ularni Excel ish varag'iga eksport qilishni umid qilishingiz mumkin. Bu erda biz buni amalga oshirish uchun 2 ta yondashuvni taqdim etamiz. Birinchisi, belgilangan elektron pochta xabarlarini topgandan so'ng, standart "Import va eksport" funksiyasidan foydalanadi. Rostini aytsam, biroz zerikarli. Shunday qilib, ikkinchisida biz sizga VBA-ni qo'llashning qulayroq usulini o'rgatamiz.

1-usul: Barcha topilgan e-pochta xabarlarini qo'lda eksport qiling

1. Avvalo, pochta ro'yxati ustidagi qidiruv maydoniga bosing.
2. Keyin, "Qidiruv" yorlig'idagi "Ko'lam" guruhidagi "Barcha pochta xabarlari" ni bosing.
3. Keyin, "Aniqlash" guruhidagi "Bayroqlangan" tugmasini bosing.
4. Ro'yxatda ko'rsatilgan barcha belgilangan elektron pochta xabarlaridan so'ng, bitta xatni tanlang va ularning barchasini tanlash uchun "Ctrl + A" ni bosing.
5. Keyin "Ctrl + Shift + V" tugmachalarini bosing.
6. Yangi dialog oynasida Outlook fayli ostida yangi papka yarating.
7. Keyinchalik, yangi yaratilgan jildni tanlang va "OK" tugmasini bosing, bu esa barcha topilgan bayroqli elektron pochta xabarlarini yangi jildga o'tkazadi.
8. Shundan so'ng, "Fayl"> "Ochish"> "Import" ni bosing,
9. Qalqib chiquvchi dialog oynasida “Faylga eksport qilish” > “Keyingi” > “Microsoft Excel 97-2003” > “Keyingi” ni tanlang.
10. Yangi ekranda to'g'ri jildni tanlang va "Keyingi" tugmasini bosing.
11. Keyinchalik, "Eksport" ni bajarish uchun sehrgarlarga amal qiling.
12. Siz quyidagi skrinshotda ko'rsatilgan yangi Excel faylini olasiz.

2-usul: Belgilangan barcha elektron pochta xabarlari ro'yxatini VBA orqali eksport qiling

1. Outlook-da VBA muharririni ishga tushirish uchun “Alt + F11” tugmasini bosing.
2. Keyin "MS Excel ob'ektini" ga muvofiq yoqing.VBA da obyekt kutubxonasi havolasini qanday qo'shish mumkin".
3. Keyin quyidagi VBA kodini modulga ko'chiring.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Nihoyat, kursorni "ExportAllFlaggedEmailsToExcel" pastki dasturiga qo'ying va "F5" tugmasini bosing.
5. Keyin yangi dialog oynasida Outlook faylini tanlang.
6. "Bajarildi" so'rovini olganingizda, siz quyidagi rasm kabi yangi Excel faylini olasiz.

Outlookni korruptsiyadan himoya qiling

Outlook xatolar va buzilishlarga moyil, shuning uchun Outlook ma'lumotlarimizni himoya qilish biz uchun juda qiyin vazifadir. Shubhasiz, eng samarali va amaliy usul Outlook uchun muntazam ravishda ma'lumotlarning zaxira nusxalarini yaratishdir. Bunga qo'shimcha ravishda, biz uchun kuchli va ishonchli Outlook tuzatish vositasini qo'lga kiritish ham zarur, masalan DataNumen Outlook Repair. Bu foydali bo'ladi, agar pochta qutisini tuzatish vositasi hech qanday ta'sir ko'rsatmaydi.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tuzatish SQL Server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com