Outlook-da jo'natuvchi tomonidan elektron pochta xabarlarini tez hisoblashning 2 usuli

Agar siz xatlarni jo'natuvchi bo'yicha hisoblashni istasangiz, ushbu maqolaga murojaat qilishingiz mumkin. Bu erda biz sizga 2 ta tezkor yondashuvni taqdim etamiz.

Siz uchun eng faol jo'natuvchini bilish uchun siz elektron pochta xabarlarini jo'natuvchilar bo'yicha sanashingiz mumkin. Outlook buning uchun to'g'ridan-to'g'ri funksiyani taqdim etmasa ham, siz hali ham ba'zi vaqtinchalik yechimlarni qidirishingiz mumkin, masalan, quyidagi 1-usul. Agar siz 1-usulni juda zerikarli deb hisoblasangiz, 2-usulni tanlashingiz mumkin. Bu ancha samaraliroq, chunki u jo'natuvchilar bo'yicha elektron pochta xabarlarini tezda sanash va ularning sonini Excelga eksport qilish uchun VBA dan foydalanadi. Endi ikkita usulni batafsil o'qing. Bu yerda biz misol sifatida Inboxdagi elektron pochta xabarlarini ko'rib chiqamiz.

1-usul: "Kimdan" maydoni bo'yicha elementlarni guruhlashdan keyin hisoblarni oling

1. Boshlash uchun Outlook dasturini ishga tushiring.
2. Keyin, kirish qutisi papkasini oching.
3. Keyin "Ko'rish" yorlig'iga o'ting.
4. Keyinchalik, "Tartibga solish" guruhida "Kimdan" ni tanlang.
5. Bir vaqtning o'zida barcha kiruvchi xabarlar turli jo'natuvchilarga qarab turli guruhlarga bo'lingan.
6. Endi ma'lum bir jo'natuvchidan kelgan narsalarni hisoblash uchun siz tegishli guruhdagi barcha elementlarni tanlashingiz va "Enter" tugmasini bosishingiz mumkin. Qalqib chiquvchi ogohlantirishda siz hisobni ko'rishingiz mumkin.

Bu juda oson, lekin ob'ektlar soni nafaqat elektron pochta hisobini emas, balki yig'ilish taklifnomalari, topshiriq so'rovlari va kvitansiyalar kabi boshqa turdagi narsalarni ham o'z ichiga oladi. Shunday qilib, agar siz faqat elektron pochta xabarlarini hisoblashni istasangiz, uning o'rniga quyidagi usuldan foydalanishingiz mumkin.

2-usul: Outlook VBA yordamida jo'natuvchining elektron pochta xabarlarini sanash

1. Boshlash uchun Outlook-da "Alt + F11" tugmachalarini bosing.
2. Keyin, "MS Excel obyektlar kutubxonasi" ga muvofiq "VBA da obyekt kutubxonasi havolasini qanday qo'shish mumkin".
3. Keyin quyidagi kodni foydalanilmagan modulga nusxalang.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Shundan so'ng, "F5" tugmachasini bosing.
4. Makros tugagach, yangi Excel fayli ko'rsatiladi.
5. Ko'rib turganingizdek, u turli jo'natuvchilardan kelgan elektron pochta xabarlarining sonini o'z ichiga oladi.

Xafagarchilik tug'diradigan Outlook muammolarini yo'q qiling

Ehtimol, siz Outlook-da ko'plab muammolarga duch kelgansiz. Ularni samarali hal qilish uchun siz ko'p qirrali va kuchli yo'lni orzu qilishingiz mumkin. Biroq, aslida, bunday usul mavjud emas. Siz qila oladigan narsa - Outlook-da o'z operatsiyalaringizdan ehtiyot bo'lish va muntazam zaxira nusxalarini yaratish. Albatta, iloji bo'lsa, tajribali tuzatish vositasini qo'lingizda ushlab turishingizni maslahat beramiz, masalan DataNumen Outlook Repair. U turli xil PST muammolarini hal qilishi va tuzatishi mumkin buzilgan PST shabada kabi fayl.

Muallif kirish:

Shirli Chjan ma'lumotlarni qayta tiklash bo'yicha mutaxassis DataNumenMa'lumotlarni qayta tiklash texnologiyalari bo'yicha jahon yetakchisi bo'lgan , Inc tiklash Sql Server va Outlook ta'mirlash dasturiy mahsulotlar. Qo'shimcha ma'lumot olish uchun tashrif buyuring www.datanumen.com